Hello,

As you probably know, it is possible to include source filename, line number, date etc. in your source
with the following directives:
{$I %FILENAME%}
{$I %LINE%}
{$i %DATE%}

At my request, Florian added

{$I %CURRENTROUTINE%}

to the list of possibilities, which means you can do nifty things as:

program testcr;
{$mode objfpc}
Type
   TMyClass = Class(TObject)
   Public
     Procedure MyMethod;
   end;
Var
   Indent : Integer;
Procedure MethodEnter(Const AMethod : String);
begin
   Writeln(StringOfChar(' ',Indent),'Entering ',AMethod);
   Inc(Indent,2);
end;
Procedure MethodExit(Const AMethod : String);
begin
   Dec(Indent,2);
   if Indent<0 then Indent:=0;
   Writeln(StringOfChar(' ',Indent),'Exiting ',AMethod);
end;
Procedure Debug(Const AMsg : String);
begin
  Writeln(StringOfChar(' ',Indent),AMsg);
end;
Procedure DoSomething;
   Procedure DoNested;
   begin
     MethodEnter({$I %CURRENTROUTINE%});
     Debug('Nested handling in '+{$I %CURRENTROUTINE%});
     MethodExit({$I %CURRENTROUTINE%});
   end;
begin
   MethodEnter({$I %CURRENTROUTINE%});
   Debug('Doing something in '+{$I %CURRENTROUTINE%}+' at line '+{$I %LINE%});
   DoNested;
   MethodExit({$I %CURRENTROUTINE%});
end;
Procedure TMyClass.MyMethod;
   Procedure DoNested;
   begin
     MethodEnter({$I %CURRENTROUTINE%});
     Debug('Nested handling in '+{$I %CURRENTROUTINE%});
     MethodExit({$I %CURRENTROUTINE%});
   end;
begin
   MethodEnter({$I %CURRENTROUTINE%});
   Debug('Doing some things in '+{$I %CURRENTROUTINE%}+' at line '+{$I %LINE%});
   DoNested;
   MethodExit({$I %CURRENTROUTINE%});
end;
Var
   T : TMyClass;
begin
   MethodEnter({$I %CURRENTROUTINE%});
   DoSomething;
   T:=TMyClass.Create;
   try
     T.MyMethod;
   finally
     T.Free;
   end;
   MethodExit({$I %CURRENTROUTINE%});
end.

Which produces something like

Entering $main
Entering DoSomething
Doing something in DoSomething at line 44
Entering DoNested
Nested handling in DoNested
Exiting DoNested
Exiting DoSomething
Entering MyMethod
Doing some things in MyMethod at line 61
Entering DoNested
Nested handling in DoNested
Exiting DoNested
Exiting MyMethod
Exiting $main

Kudos to Florian.

Michael.

Michael Van Canneyt wrote

At my request, Florian added {$I %CURRENTROUTINE%}

Oh wow, that will be super handy! (For the fpprofiler too.) Many thanks for that one.

Regards,
- Graeme -

At least it looks as ugly as possible so nobody will use this too much :)

A profiler should use debug info imo.

Agreed that it is ugly, but indispensibe when programming webservers.

Michael.

I usually use hardcoded strings for that, so this makes my coding life easier :)
Thanks!

Add I created code template for it: "icr" and it writes?{$I %CURRENTROUTINE%} itself :-) ?
V.
______________________________________________________________

I usually use hardcoded strings for that, so this makes my coding life easier :)
Thanks!

Simply use $ProcedureName() in your template

   EnterSomething('$ProcedureName()');

Of course it does not update if you rename the procedure, but otherwise it is fine.
-------------- next part --------------
An HTML attachment was scrubbed...
URL: <http://lists.lazarus.freepascal.org/pipermail/lazarus/attachments/20150517/ce6d6533/attachment.html>

Florian Kl?mpfl wrote

A profiler should use debug info imo.

True, but the fpprofiler is a quick and easy one (though basic), if no others are available.

Regards,
- Graeme -

Martin Frb wrote

Simply use $ProcedureName() in your template EnterSomething('$ProcedureName()');

That is what I've been using up to now, but is problematic if you switch between IDE's or programmer editors to do coding (I do this often). At least the new directive will be universally supported.

Regards,
- Graeme -

On Sun, May 17, 2015 at 5:50 AM, Michael Van Canneyt <

Thanks for this nice feature! =)

I'll use it in a new logger class that I'm implementing.

(y)