TTaskDialog class

Declaration

TTaskDialog = class(TCustomTaskDialog)

Inheritance

1. TTaskDialog
2. TCustomTaskDialog
3. TLCLComponent
4. TComponent

Description

TTaskDialog is a TCustomTaskDialog descendant which implements a configurable, modal task dialog. It can be used to display and edit information on a dialog form with more features than those available on a standard message box.

TTaskDialog sets the visibility for properties introduced in ancestor classes, and provides a multi-platform implementation of the Windows TaskDialog API. It provides properties which can be used to configure the task dialog at design-time or at run-time. At run-time, the Execute method handles converting properties and calling routines and methods in the widgetset which implement the task dialog for a given platform.

Platform Support

The TaskDialog API, upon which TTaskDialog is based, is available only on Windows Vista or later versions. On these platforms, the form displayed at run-time is the native form for the platform. On older Windows versions, and other platforms, the TaskDialog API is not available or supported. For these platforms, a standard LCL form is created and populated at run-time to emulate the appearance and behaviors for the Windows implementation. This occurs in the widget set class and uses the components found in the taskdlgemulation.pp unit. It can be forced by including a value in the Flags property for the class instance.

Using TTaskDialog at Run-time.

procedure TForm1.Button1Click(Sender: TObject);
  var ATaskDialog: TTaskDialog; // requires Dialogs in uses clause
begin
  ATaskDialog := TTaskDialog.Create(Self);
  with ATaskDialog do
  begin
     Caption := 'Let''s do this...';
     MainIcon := tdiShield;
     Title := 'Task Title';

    Text := 'This tells the user the purpose for the dialog. ' +
      'Please read and accept the Terms of Service. '+#10+#10+
      'Some users prefer a little conversation before they will agree. ' +
      'Along with a progress bar. Please tell us your level of interest.';

    RadioButtons.Clear;
    RadioButtons.Add.Caption := 'Low';
    RadioButtons.Add.Caption := 'Medium';
    RadioButtons.Add.Caption := 'High';

    CommonButtons := [tcbOk,tcbCancel,tcbRetry];

    ExpandedText := 'The Terms of Service grants a waiver of responsibility '+
      'to Acme Corporation LLC for any insane acts a Coyote might perform '+
      'using products or services provided by the Corporation.'+#10+#10+
      'There is no legal venue where the Corporation is responsible. ' +
      'Especially Albuquerque, NM USA. ' +#10+#10+
      'Buyer beware. All rights reserved. Shipping fees and taxes may apply.';

    VerificationText := 'I agree to everything.';

    FooterIcon := tdiWarning;
    FooterText := 'This is your <a href="#terminus">final</a> warning.';

    Flags := [tfEnableHyperlinks, tfAllowDialogCancellation, 
      tfExpandedByDefault, tfVerificationFlagChecked];

    if Execute then ; // do something based on ModalResult
    Free;
  end;
end;

See also

• TCustomTaskDialog
• TLCLTaskDialog

Properties

Events

Inherited