Sign in Join
Wiki copytemporary

Translations / i18n / localizations for programs/de: what changed

Revision 0 to 1. Removed lines have a minus sign; added lines have a plus sign.

Title: Translations / i18n / localizations for programs/de

OldNewLine
1+Zurück zu den [[Additional information/de|Zusätzlichen Informationen]].\
2+
3+== Überblick ==
4+
5+Hier wird gezeigt, wie Sie in Ihrem Programm verschiedene Strings für verschiedene Sprachen (Englisch, Deutsch, Chinesisch...) ausgeben können. Dazu müssen Sie nur Folgendes tun: Einen *resourcestring* für jeden String, den Sie ausgeben möchten hinzufügen, kompilieren um .rst und/oder .po Dateien zu erhalten (kann die IDE automatisch erzeugen), für jede Sprache eine .po Datei erstellen (dazu gibt es graphische Programme), und zuletzt die richtige .po Datei beim Programmstart mittels der Unit *translations* laden.
6+
7+## Schnell i18n
8+
9+Dies soll ein Schnelleinstig sein, der Übersetzungen kurz und bündig vorstellt.
10+
11+### poedit
12+
13+Das bekannteste Werkzeug ist [Poedit](https://poedit.net/). Poedit ist ein Übersetzungswerkzeug, das .po und .mo-Dateien erstellt.
14+
15+### Resourcestrings übersetzen
16+
17+Auf folgende Weise wird ein Ressourcestring einer Unit erzeugt:
18+
19+``` pascal
20+resourcestring
21+ Caption1 = 'Ein Text';
22+ HelloWorld1 = 'Hello World';
23+```
24+
25+Resourcestrings verhalten sich wie normale Stringkonstanten, das heißt, man kann sie einfach so verwenden:
26+
27+``` pascal
28+Label1.Caption := HelloWorld1;
29+```
30+
31+### Beim Compilieren .po-Dateien erstellen
32+
33+Wenn man i18n in der Lazarus IDE einschaltet werden Resourcestrings zu .po-Dateien compiliert. i18n findet man unter Projekt \> Projekteinstellungen \> i18n \> i18n einschalten. Beim erneuten compilieren werden die .po-Dateien aktualisiert. Man kann ebenfalls das Verzeichnis festlegen, in dem die .po-Dateien gespeichert werden. (Empfohlen wird **po files**)
34+
35+Die empfohlene voreingestellte Übersetzung oder Applications-Sprache sollte Englisch sein, da sie geladen wird, wenn keine passende Übersetzung gefunden wird.
36+
37+Ist die **project1.po**-Datei erstellt, muss man sie in **project1.\<Sprache\>.po** umbenennen, wobei \<Sprache\> für das Kürzel der jeweiligen Sprache steht z.B: **project1.es.po** für Spanisch. Diese muss man nun zum Übersetzen geben.
38+
39+Die Verzeichniss-Struktur sieht nun ungefähr so aus:
40+
41+``` pascal
42+project1\po_files\
43+project1\po_files\project1.po
44+project1\po_files\project1.es.po
45+```
46+
47+### .po-Dateien umwandeln zu .mo-Dateien
48+
49+Wenn die .po-Datei fertig übersetzt ist, sollte man sie in eine .mo-Datei compilieren, da dieses Binärformat schneller geladen wird. Für die Konvertierung in das .mo-Format eignet sich z.B. [Poedit](https://poedit.net/) ( Datei -\> MO-Datei erstellen ... ).
50+
51+### Automatische Übersetzung
52+
53+Wenn alle .mo-Dateien fertig sind, werden sie in das Verzeichnis **locale** oder **languages** direkt unterhalb des Anwendungsprogramms gespeichert. Dann wird noch die Unit **DefaultTranslator** eingebunden und das war schon alles. Die Übersetzung erfolgt automatisch.
54+
55+``` pascal
56+uses
57+ DefaultTranslator;
58+```
59+
60+Es sollten nur die .mo-Dateien im **locale** or **languages** Verzeichnis ausgeliefert werden, da die .po-Dateien nur für die Anfertigung der Übersetzung und die Compilierung in .mo-Dateien benötigt werden.
61+
62+Die Verzeichnissstruktur wird so aussehen:
63+
64+``` pascal
65+project1\project1.exe
66+project1\locale\
67+project1\locale\project1.mo
68+project1\locale\project1.es.mo
69+```
70+
71+## Zusätzliche Informationen
72+
73+## Datums-, Zeit- und Zahlenformat
74+
75+In der Unit [sysutils](http://www.freepascal.org/docs-html/rtl/sysutils/index.html) sind verschiedene Format-Zeichen definiert, mit denen Datum und Zeit oder Dezimalzahlen formatiert werden. Unter POSIX-konformen Betriebssystemen wie Linux oder Mac OS X können diese von der Unit clocale automatisch aus der Standard C Library übernommen werden. Dazu muss die Unit nur in das Programm (.lpr) aufgenommen werden:
76+
77+``` pascal
78+uses
79+ {$IFDEF UNIX}
80+ {$IFDEF UseCThreads}cthreads,{$ENDIF}
81+ clocale,{$ENDIF}
82+ Interfaces, // this includes the LCL widgetset
83+ Forms, Unit1
84+ { you can add units after this };
85+```
86+
87+## Ressourcenstrings
88+
89+Ressourcenstrings verhalten sich ähnlich wie String-Konstanten, können aber zur Laufzeit übersetzt werden.
90+
91+Eine Definition sieht so aus:
92+
93+``` pascal
94+resourcestring
95+ Caption1 = 'Irgendein Text';
96+ HelloWorld1 = 'Hello World';
97+```
98+
99+Nun kann man sie wie normale String-Konstanten verwenden. Wurden sie bereits übersetzt, wird nicht mehr der originale Inhalt sondern die Übersetzung zugewiesen:
100+
101+``` pascal
102+Label1.Caption := HelloWorld1;
103+```
104+
105+Wenn der FPC eine Unit mit einem resourcestring-Abschnitt übersetzt, erzeugt er automatisch eine Datei **unitname.rst**, in der alle Resourcestring-Daten (Name + Inhalt) zu dieser Unit gespeichert werden.
106+
107+## .po Dateien
108+
109+*.po* Dateien sind genau wie die *.rst* Dateien einfache Textdateien, enthalten aber ein paar mehr Optionen, wie einen Header, in dem Felder für Autor, Kodierung (Zeichensatz), Sprache und Datum vorgesehen sind. Daher können sie mit jedem Texteditor bearbeitet werden. Es gibt aber viele freie, grafische Tools um *.po* Dateien um diese Aufgabe bequemer zu erledigen (z.B. mit [kbabel](http://kbabel.kde.org/), [Poedit](http://www.poedit.net/)).
110+
111+Jede fpc Installation enthält das Programm **rstconv** (unter Windows *rstconv.exe*). Dieses Werkzeug kann verwendet werden, um eine .rst Datei in eine .po Datei zu konvertieren. Die IDE kann dies aber automatisch erledigen (einzustellen in den Projektoptionen, siehe unten).
112+
113+Beispiel wie rstconv direkt verwendet wird:
114+
115+` rstconv -i unit1.rst -o unit1.po`
116+
117+## Übersetzen
118+
119+Für jede Sprache muss die .po-Datei kopiert und übersetzt werden. Einige Tipps zum Übersetzen finden Sie unter: [[Getting translation strings right/de|Wie man Übersetzungsstrings richtig hinbekommt]].
120+
121+Die LCL Unit *translation* sucht nach den übersetzen .po-Dateien nach dem Schema: *unitname.\<Sprachkürzel\>.po*, wobei \<Sprachkürzel\> dem üblichen Sprachcode (en=English, de=Deutsch, it=Italienisch, ...) entspricht. Die deutsche Übersetzung für *unit1.po* wäre also in *unit1.de.po* zu finden. Legen Sie also für jede Sprache, die Sie anbieten wollen, eine Kopie der Originaldatei an und übersetzen Sie diese.
122+
123+**Anmerkung für Brasilianer/Portugiesen:**: Lazarus IDE und LCL haben nur eine Übersetzung für brasilianisches Portugiesisch und diese Dateien enden auf 'pb.po' und nicht auf 'pt.po'.
124+
125+## IDE Einstellungen für automatische Updates der .po Dateien
126+
127+- Die Unit, die die Ressourcenstrings enthält, muss zum Package oder Projekt hinzugefügt sein.
128+- Sie müssen einen .po Pfad angeben. Dies bedeutet ein separates Verzeichnis. Zum Beispiel: erzeugen sie ein Unterverzeichnis *languages* im Package / Projekt Verzeichnis.\
129+
130+Für Projekte wählen Sie im Menü Projekt \> Projekteinstellungen -\> i18n.\
131+Für Packages wählen Sie in den Package-Einstellungen 'i18n'.
132+
133+Wenn diese Optionen aktiviert sind, dann erzeugt bzw. aktualisiert die IDE die zugrundeliegende .po-Datei und benutzt dazu die Informationen aus den .rst und .lrt-Dateien (das rstconv Werkzeug ist dann nicht notwendig). Der Aktualisierungsvorgang beginnt damit, alle bestehenden Einträge aus der grundlegenden .po-Datei sowie aus den .rst und .lrt-Dateien zu sammeln, und wendet dann die nachfolgend gefundenen Merkmale an und aktualisiert so jede übersetzte .xx.po Datei.
134+
135+### Entfernen überflüssiger Einträge
136+
137+Einträge aus der grundlegenden .po Datei, die nicht in .rst und .lrt-Dateien zu finden sind, werden entfernt. Anschließend werden ebenso all jene Einträge entfernt, die zwar in den übersetzten .xx.po Dateien vorkommen, aber nicht in der .po-Datei stehen. Auf diese Weise werden die .po Dateien nicht mit obsoleten Einträgen zugemüllt und die Übersetzer müssen keine Einträge bearbeiten, die gar nicht mehr verwendet werden.
138+
139+### Mehrfache Einträge
140+
141+Mehrfache Einträge treten dann auf, wenn derselbe Text für verschiedene Ressourcenstrings als Übersetzung steht. Ein Beispiel dafür findet man in der Datei 'lazarus/ide/lazarusidestrconst.pas' für den 'Gutter' String:
142+
143+``` pascal
144+ dlfMouseSimpleGutterSect = 'Gutter';
145+ dlgMouseOptNodeGutter = 'Gutter';
146+ dlgGutter = 'Gutter';
147+ dlgAddHiAttrGroupGutter = 'Gutter';
148+```
149+
150+Eine konvertierte .rst-Datei für diese Ressourcenstrings würde ähnlich aussehen wie die folgende .po-Datei:
151+
152+`#: lazarusidestrconsts.dlfmousesimpleguttersect`\
153+`msgid "Gutter"`\
154+`msgstr ""`\
155+`#: lazarusidestrconsts.dlgaddhiattrgroupgutter`\
156+`msgid "Gutter"`\
157+`msgstr ""`\
158+`etc.`\
159+
160+Wobei die mit "#: " beginnenden Zeilen als Kommentare betrachtet werden und die zum Übersetzen dieser Einträge verwendeten Werkzeuge die wiederholten msgid "Gutter" Zeilen als mehrfache Einträge ansehen und Fehler oder Warnhinweise beim Laden oder Speichern produzieren. Mehrfache Einträge treten bei .po-Dateien häufig auf und deshalb ist es nötig, sie durch einen angehängten Kontext näher zu bestimmen. Das Schlüsselwort 'msgctxt' fügt einen Kontext an einen der mehrfachen Einträge an. Das Werkzeug zum automatischen Aktualisieren verwendet die Eintrags-ID (das ist der Text neben dem "#: " Präfix) als Kontext. Im vorigen Beispiel würde es ungefähr folgendes liefern:
161+
162+`#: lazarusidestrconsts.dlfmousesimpleguttersect`\
163+`msgctxt "lazarusidestrconsts.dlfmousesimpleguttersect"`\
164+`msgid "Gutter"`\
165+`msgstr ""`\
166+`#: lazarusidestrconsts.dlgaddhiattrgroupgutter`\
167+`msgctxt "lazarusidestrconsts.dlgaddhiattrgroupgutter"`\
168+`msgid "Gutter"`\
169+`msgstr ""`\
170+`etc.`\
171+
172+Bei übersetzten .xx.po Dateien macht das automatische Tool eine zusätzliche Überprüfung: wenn der mehrfache Eintrag bereits übersetzt wurde, übernimmt der neue Eintrag die alte Übersetzung, sodass er wie automatisch übersetzt erscheint.
173+
174+Die automatische Erkennung von Duplikaten ist noch nicht perfekt. Die Erkennung wird jedes Mal durchgeführt, wenn neue Einträge hinzugefügt werden. Es kann aber passieren, dass einige nicht übersetzte Einträge zuerst gelesen werden. Daher können mehrere Durchläufe notwendig sein, damit das Werkzeug alle Duplikate automatisch übersetzen kann.
175+
176+### Merkwürdige Einträge
177+
178+Änderungen an Ressourcenstrings beeinflussen die Übersetzungen.\
179+(Das folgende Beispiel wurde aus der Lazarus history entnommen)\
180+Wenn z. B. ein Ressourcenstring anfänglich wie folgt definiert war:
181+
182+``` pascal
183+ dlgEdColor = 'Syntax highlight';
184+```
185+
186+Dies erzeugt einen ähnlichen .po Eintrag wie diesen:
187+
188+`#: lazarusidestrconsts.dlgedcolor`\
189+`msgid "Syntax highlight"`\
190+`msgstr ""`
191+
192+der in der spanischen Übersetzung resultiert in
193+
194+`#: lazarusidestrconsts.dlgedcolor`\
195+`msgid "Syntax highlight"`\
196+`msgstr "Color"`
197+
198+Angenommen, dass zu einem späteren Zeitpunkt der Ressourcenstring geändert würde in
199+
200+``` pascal
201+ dlgEdColor = 'Colors';
202+```
203+
204+dann ändert sich auch der .po Eintrag in
205+
206+`#: lazarusidestrconsts.dlgedcolor`\
207+`msgid "Colors"`\
208+`msgstr ""`
209+
210+Beachten Sie, dass zwar die ID 'lazarusidestrconsts.dlgedcolor' gleich geblieben ist, sich aber der String geändert hat, von 'Syntax highlight' zu 'Colors'. Weil der String bereits übersetzt war, könnte die alte Übersetzung nicht zu der neuen Bedeutung passen. Und wirklich, für unseren neuen String wäre im Spanischen wahrscheinlich 'Colores' die bessere Übersetzung. Das automatische Aktualisierungwerkzeug erkennt diese Situation und erzeugt einen Eintrag wie diesen:
211+
212+`#: lazarusidestrconsts.dlgedcolor`\
213+`#, fuzzy`\
214+`#| msgid "Syntax highlight"`\
215+`msgctxt "lazarusidestrconsts.dlgedcolor"`\
216+`msgid "Colors"`\
217+`msgstr "Color"`
218+
219+Im Zusammenhang des .po Dateiformates, bedeutet das "#," Präfix, dass der Eintrag ein Flag (namens 'fuzzy') hat. Ein geeignetes Übersetzungsprogramm könnte dieses Flag auswerten. Der Übersetzer sieht dadurch bei diesem Eintrag sofort, dass die Übersetzung in ihrem derzeitigen Zustand fragwürdig ist und somit einer Überprüfung durch den Übersetzer bedarf.\
220+Das "#\|" Präfix weist darauf hin, dass der vorhergehende String unübersetzt ist und liefert auch einen Hinweis darauf, warum der Eintrag als 'fuzzy' markiert war.
221+
222+## Übersetzung von Formularen, Datenmodulen und Frames
223+
224+Wenn die i18n Einstellung für das Projekt / Package aktiviert ist, dann erzeugt die IDE automatisch .lrt Dateien für jedes Formular. Die .lrt Dateien werden beim Speichern einer Unit erzeugt. Wenn sie die Einstellung zum ersten Mal aktivieren, dann müssen Sie jedes Formular einmal öffnen und eine Änderung vornehmen (damit es als geändert markiert ist) und dann speichern.
225+
226+**Beispiel:** Wenn Sie ein Formular *unit1.pas* speichern, erstellt die IDE die Datei *unit1.lrt*. Beim Kompilieren sammelt die IDE alle Strings aus allen *.lrt* und *.rst* Dateien in einer einzigen *.po* Datei (projektname.po oder paketname.po) in dem i18n Verzeichnis.
227+
228+Damit die Formulare zur Laufzeit tatsächlich übersetzt werden, müssen Sie der Objektvariablen 'LRSTranslator' (definiert in LResources) im Abschnitte initialization einer Ihrer Units ein Translator-Objekt zuweisen
229+
230+``` pascal
231+...
232+uses
233+ ...
234+ LResources;
235+...
236+...
237+initialization
238+ LRSTranslator:=TPoTranslator.Create('/Pfad/zu/der/po/Datei');
239+```
240+
241+Allerdings gibt es derzeit in der LCL keine TPoTranslator - Klasse (das ist eine Klasse, die unter Verwendung von .po Dateien übersetzt). Hier folgt eine mögliche Implementierung (teilweise entlehnt aus DefaultTranslator.pas in der LCL):Der folgende Code wird nicht mehr länger gebraucht, wenn Sie einen aktuellen Lazarus 0.9.29 Snapshot einsetzen. Fügen Sie einfach 'DefaultTranslator' zur Uses-Klausel hinzu.
242+
243+``` pascal
244+unit PoTranslator;
245+
246+{$mode objfpc}{$H+}
247+
248+interface
249+
250+uses
251+ Classes, SysUtils, LResources, typinfo, Translations;
252+
253+type
254+
255+ { TPoTranslator }
256+
257+ TPoTranslator=class(TAbstractTranslator)
258+ private
259+ FPOFile:TPOFile;
260+ public
261+ constructor Create(POFileName:string);
262+ destructor Destroy;override;
263+ procedure TranslateStringProperty(Sender:TObject;
264+ const Instance: TPersistent; PropInfo: PPropInfo; var Content:string);override;
265+ end;
266+
267+implementation
268+
269+{ TPoTranslator }
270+
271+constructor TPoTranslator.Create(POFileName: string);
272+begin
273+ inherited Create;
274+ FPOFile:=TPOFile.Create(POFileName);
275+end;
276+
277+destructor TPoTranslator.Destroy;
278+begin
279+ FPOFile.Free;
280+ inherited Destroy;
281+end;
282+
283+procedure TPoTranslator.TranslateStringProperty(Sender: TObject;
284+ const Instance: TPersistent; PropInfo: PPropInfo; var Content: string);
285+var
286+ s: String;
287+begin
288+ if not Assigned(FPOFile) then exit;
289+ if not Assigned(PropInfo) then exit;
290+{DO we really need this?}
291+ if Instance is TComponent then
292+ if csDesigning in (Instance as TComponent).ComponentState then exit;
293+{End DO :)}
294+ if (AnsiUpperCase(PropInfo^.PropType^.Name)<>'TTRANSLATESTRING') then exit;
295+ s:=FPOFile.Translate(Content, Content);
296+ if s<>'' then Content:=s;
297+end;
298+
299+end.
300+```
301+
302+Alternativ dazu können Sie (mit 'msgfmt') die .po Datei in eine .mo Datei umwandeln und einfach die Unit 'DefaultTranslator' verwenden
303+
304+``` pascal
305+...
306+uses
307+ ...
308+ DefaultTranslator;
309+```
310+
311+Diese sucht automatisch in verschiedenen Standard-Verzeichnissen nach einer .mo Datei (der Nachteil dabei ist, dass Sie beiderlei Dateien behalten müssen, die .mo Dateien für die DefaultTranslator-Unit und die .po Dateienfiles für TranslateUnitResourceStrings). Wenn Sie DefaultTranslator benutzen, wird er automatisch versuchen die Sprache anhand der Umgebungsvariablen LANG zu bestimmen. (Dies kann mit dem Befehlszeilenschalter --lang überschrieben werden). Anschließend wird an folgenden Stellen nach einer Übersetzung gesucht (hier bedeutet LANG die gesuchte Sprache):
312+
313+- \<Application Directory\>/LANG/\<Application Filename\>.mo
314+- \<Application Directory\>/languages/LANG/\<Application Filename\>.mo
315+- \<Application Directory\>/locale/LANG/\<Application Filename\>.mo
316+- \<Application Directory\>/locale/LC_MESSAGES/LANG/\<Application Filename\>.mo
317+
318+unter Unix-ähnliche Betriebssystemen wird auch gesucht in
319+
320+- /usr/share/locale/LANG/LC_MESSAGES/\<Application Filename\>.mo
321+
322+ebenso wird die Kurzform des Sprachbezeichners probiert (wenn z.B. "es_ES" oder "es_ES.UTF-8" nicht existieren wird auch "es" versucht).
323+
324+## Übersetzung beim Start eines Programms
325+
326+Für jede .po Datei müssen sie TranslateUnitResourceStrings aus der LCL Unit Translations aufrufen. Zum Beispiel:
327+
328+``` pascal
329+uses
330+ ..., GetText, Translations;
331+
332+procedure TForm1.FormCreate(Sender: TObject);
333+var
334+ PODirectory, Lang, FallbackLang: String;
335+begin
336+ PODirectory := 'C:\Lazarus\lcl\languages\'; //Pfad entsprechend Installation anpassen !!!
337+ GetLanguageIDs(Lang, FallbackLang);
338+ Translations.TranslateUnitResourceStrings('LCLStrConsts', PODirectory + 'lclstrconsts.%s.po', Lang, FallbackLang);
339+ // ... fügen Sie hier einen Aufruf von TranslateUnitResourceStrings für jede .po-Datei hinzu ...
340+
341+ // der folgende Dialog zeigt übersetzte Buttons:
342+ MessageDlg('Title', 'Text', mtInformation, [mbOk, mbCancel, mbYes], 0);
343+end;
344+```
345+
346+## .po Dateien in die Programmdatei kompilieren
347+
348+Wenn Sie die einzelnen .po Dateien nicht zusammen mit Ihrer Anwendung installieren, sondern mit in die Programmdatei packen wollen, gehen Sie wie folgt vor:
349+
350+- Erzeugen Sie eine neue Unit (kein Formular!).
351+- Konvertieren Sie die .po Datei(en) in .lrs unter Verwendung von tools/lazres:
352+
353+ ./lazres unit1.lrs unit1.de.po
354+
355+Dadurch wird eine Include-Datei unit1.lrs erstellt, die folgendermaßen beginnt
356+
357+``` pascal
358+LazarusResources.Add('unit1.de','PO',[
359+ ...
360+```
361+
362+- Fügen Sie den Code hinzu:
363+
364+``` pascal
365+uses LResources, Translations;
366+
367+resourcestring
368+ MyCaption = 'Caption';
369+
370+function TranslateUnitResourceStrings: boolean;
371+var
372+ r: TLResource;
373+ POFile: TPOFile;
374+begin
375+ r:=LazarusResources.Find('unit1.de','PO');
376+ POFile:=TPOFile.Create(False); //if Full=True then you can get a crash (Issue #0026021)
377+ try
378+ POFile.ReadPOText(r.Value);
379+ Result:=Translations.TranslateUnitResourceStrings('unit1',POFile);
380+ finally
381+ POFile.Free;
382+ end;
383+end;
384+
385+initialization
386+ {$I unit1.lrs}
387+```
388+
389+- Rufen Sie TranslateUnitResourceStrings am Beginn des Programms auf. Wenn Sie wollen, können Sie das im Abschnitt "initialization" machen.
390+
391+Leider wird dieser Code mit Lazarus 1.2.2 und früher nicht kompiliert, für diese Lazarusversionen können Sie wie folgt verfahren:
392+
393+``` pascal
394+type
395+ TTranslateFromResourceResult = (trSuccess, trResourceNotFound, trTranslationError);
396+
397+function TranslateFromResource(AResourceName, ALanguage : String): TTranslateFromResourceResult;
398+var
399+ LRes : TLResource;
400+ POFile : TPOFile = nil;
401+ SStream : TStringStream = nil;
402+begin
403+ Result := trResourceNotFound;
404+ LRes := LazarusResources.Find(AResourceName + '.' + ALanguage, 'PO');
405+ if LRes <> nil then
406+ try
407+ SStream := TStringStream.Create(LRes.Value);
408+ POFile := TPoFile.Create(SStream, False);
409+ try
410+ if TranslateUnitResourceStrings(AResourceName, POFile) then Result := trSuccess
411+ else Result := trTranslationError;
412+ except
413+ Result := trTranslationError;
414+ end;
415+ finally
416+ if Assigned(SStream) then SStream.Free;
417+ if Assigned(POFile) then POFile.Free;
418+ end;
419+end;
420+```
421+
422+Anwendungsbeispiel:
423+
424+``` pascal
425+initialization
426+ {$I lclstrconsts.de.lrs}
427+ TranslateFromResource('lclstrconsts', 'de');
428+end.
429+```
430+
431+## Cross-Plattform-Methode, um Systemsprache festzustellen
432+
433+Die folgende Funktion liefert einen String, der die Sprache der Benutzeroberfläche darstellt. Sie unterstützt Linux, Mac OS X und Windows.
434+
435+``` pascal
436+uses
437+ Classes, SysUtils {fügen Sie zusätzliche Units, die von Ihrem Code genutzt werden hier ein}
438+ {$IFDEF win32}
439+ , Windows
440+ {$ELSE}
441+ , Unix
442+ {$IFDEF LCLCarbon}
443+ , MacOSAll
444+ {$ENDIF}
445+ {$ENDIF}
446+ ;
447+```
448+
449+``` pascal
450+function GetOSLanguage: string;
451+{Plattform-unabhängige Verfahren, um die Sprache der Bedienoberfläche zu lesen}
452+var
453+ l, fbl: string;
454+ {$IFDEF LCLCarbon}
455+ theLocaleRef: CFLocaleRef;
456+ locale: CFStringRef;
457+ buffer: StringPtr;
458+ bufferSize: CFIndex;
459+ encoding: CFStringEncoding;
460+ success: boolean;
461+ {$ENDIF}
462+begin
463+ {$IFDEF LCLCarbon}
464+ theLocaleRef := CFLocaleCopyCurrent;
465+ locale := CFLocaleGetIdentifier(theLocaleRef);
466+ encoding := 0;
467+ bufferSize := 256;
468+ buffer := new(StringPtr);
469+ success := CFStringGetPascalString(locale, buffer, bufferSize, encoding);
470+ if success then
471+ l := string(buffer^)
472+ else
473+ l := '';
474+ fbl := Copy(l, 1, 2);
475+ dispose(buffer);
476+ {$ELSE}
477+ {$IFDEF LINUX}
478+ fbl := Copy(GetEnvironmentVariable('LC_CTYPE'), 1, 2);
479+ {$ELSE}
480+ GetLanguageIDs(l, fbl);
481+ {$ENDIF}
482+ {$ENDIF}
483+ Result := fbl;
484+end;
485+```
486+
487+## Übersetzen der IDE
488+
489+### Dateien
490+
491+Die .po Dateien der IDE befinden sich im Lazarus-Verzeichnis:
492+
493+- lazarus/languages/: Zeichenketten für die IDE
494+- lcl/languages/: Zeichenketten für die LCL
495+- ideintf/languages/: Zeichenketten für das IDE Interface
496+
497+### Übersetzer
498+
499+- Die deutsche Übersetzung wird von Jörg Braun gepflegt.
500+- Die finnische Übersetzung wird von Seppo Suurtarla gepflegt.
501+- Die russische Übersetzung wird von Maxim Ganetsky gepflegt.
502+
503+Bevor Sie mit einer neuen Übersetzung beginnen, fragen Sie besser auf der Mailing-Liste, ob schon jemand daran arbeitet.
504+
505+Bitte lesen Sie sorgfältig: [[Lazarus Documentation/de|Übersetzungen]]
506+
507+## Siehe auch
508+
509+- [[IDE Development|IDE Development: Translations, i18n, lrt, po files]]
510+- [[Getting translation strings right]]
511+- [[Lazarus Documentation|Translating/Internationalization/Localization]]
512+- [[German localization notes]]
513+
514+---
515+*From the Free Pascal wiki, page "Translations / i18n / localizations for programs/de", as it stood on 2020-03-01 after a change by Trev, out of the wiki's dump of 2024-05-26. Copyright stays with the author who wrote it, according to the old wiki's [[Licensing]] page. If you have concerns about this material, [message the admin](/wiki-contact).*

Back to history