Sign in Join
Wiki copytemporary

Streaming components/fr: what changed

Revision 0 to 1. Removed lines have a minus sign; added lines have a plus sign.

Title: Streaming components/fr

OldNewLine
1+## Introduction
2+
3+Normalement, quand vous voulez stocker des données sur le disque ou le réseau, vous devez écrire le code pour le chargement et l'enregistrement de chaque propriété. Ce tutoriel décrit comment écrire des classes qui peuvent être chargées et enregistrées à partir de flux sans charge supplémentaire de code de chargement/enregistrement, tout cela en utilisant la **RTTI**.
4+
5+Vous trouverez un exemple dans les sources de Lazarus démontrant comment enregistrer un **TGroupBox** avec un enfant **TCheckBox** vers un flux et relire ce flux pour créer une copie des deux composants. Voir \<lazaruspath\>/examples/componentstreaming/
6+
7+En combinaison avec [[RTTI controls/fr|Les contrôles RTTI]], vous pouvez réduire au minimum la quantité de code nécessaire pour connecter les données du programme avec le GUI et le Disque/Réseau.
8+
9+## TComponent / TPersistent
10+
11+La classe **TPersistent** est définie dans l'unité **Classes** et utilise la directive de compilation **{\$M+}** . Cette directive dit au compilateur de créer de l'information pendant le temps d'exécution (**RTTI**). Lui et tous ses descendants comprennent alors une nouvelle section de classe **published**. Les propriétés **published** sont visibles comme si elles étaient **public**, mais leur structure est aussi accessible pendant le temps d'exécution. Cela signifie que toute propriété **published** peut être lue et écrite pendant ce temps d'exécution. Par exemple, l'EDI emploie cette technique pour travailler avec des composants dont il n'a jamais entendu parler.
12+
13+**TComponent** étend les possibilités de **TPersistent** par sa capacité à posséder des composants enfants. Cette capacité est importante pour le traitement des flux : un composant est le composant racine (appelé parfois **lookup root**) qui gère une liste de composants enfants.
14+
15+## TReader / TWriter
16+
17+Ce sont les classes qui permettent d'écrire/de lire un **TComponent** vers/depuis un flux (Voir **CreateLRSReader** et **CreateLRSWriter**). Elles emploient un **Pilote** pour lire/écrire dans un format spécial. A l'heure actuelle, il y a un lecteur (**TLRSObjectReader**), un outil d'écriture (**TLRSObjectWriter**) pour le format d'objet binaire défini dans l'unité **LResources** et un outil d'écriture (**TXMLObjectWriter**) pour **TDOMDocument** défini dans **Laz_XMLStreaming**. L'unité **LResources** contient également des fonctions pour convertir le format binaire en texte et l'inverse (**LRSObjectBinaryToText**, **LRSObjectTextToBinary**). La bibliothèque LCL utilise de préférence le codage **UTF8** pour les chaînes de caractères tandis que Delphi préfère **Widestrings** . Par conséquent, vous disposez aussi de quelques fonctions de conversion si bien que vous pouvez tout aussi bien travailler avec des données de flux provenant de Lazarus qu'avec des données au format binaire de Delphi.
18+
19+## Streaming Collections
20+
21+Consultez [[TCollection/fr|TCollection/fr#Streaming]]
22+
23+Il s'agit d'un exemple complet qui montre comment utiliser les classes **TCollectionItem**, **TCollection** et les gérer par des flux grâce à **TComponent**.
24+
25+## Écrire votre propre composant - Partie 1
26+
27+Un composant personnalisé peut être aussi simple que :
28+
29+`type`\
30+` TMyComponent = class(TComponent)`\
31+` private`\
32+`   FID: integer;`\
33+` published`\
34+`   property ID: integer read FID write FID;`\
35+` end;`
36+
37+## Écrire un composant dans un flux
38+
39+L'unité [[doc:lcl/lresources|LResources]] a une fonction pour cela :
40+
41+` procedure WriteComponentAsBinaryToStream(AStream: TStream; AComponent: TComponent);`
42+
43+Elle écrit un composant dans le format binaire du flux. Par exemple :
44+
45+ procedure TForm1.Button1Click(Sender: TObject);
46+ var
47+ AStream: TMemoryStream;
48+ begin
49+ AStream:=TMemoryStream.Create;
50+ try
51+ WriteComponentAsBinaryToStream(AStream,AGroupBox);
52+ ... enregistre le flux quelque part ...
53+ finally
54+ AStream.Free;
55+ end;
56+ end;
57+
58+## Lecture d'un composant depuis un flux
59+
60+L'unité **LResources** a une fonction pour cela :
61+
62+` procedure ReadComponentFromBinaryStream(AStream: TStream;`\
63+`   var RootComponent: TComponent; OnFindComponentClass: TFindComponentClassEvent; TheOwner: TComponent = nil);`
64+
65+- **AStream** est le flux contenant un composant au format binaire.
66+- **RootComponent** est soit un composant existant dont les données seront écrasées, soit c'est **nil** et un nouveau composant sera créé.
67+- **OnFindComponentClass** est une fonction qui est utilisée par **TReader** pour obtenir la classe à partir des noms de classe dans le flux. Par exemple :
68+
69+ procedure TCompStreamDemoForm.OnFindClass(Reader: TReader;
70+ const AClassName: string; var ComponentClass: TComponentClass);
71+ begin
72+ if CompareText(AClassName,'TGroupBox')=0 then
73+ ComponentClass:=TGroupBox
74+ else if CompareText(AClassName,'TCheckBox')=0 then
75+ ComponentClass:=TCheckBox;
76+ end;
77+
78+- **TheOwner** est le propriétaire du composant pendant la création d'un nouveau composant.
79+
80+## Propriétés pouvant être stockées dans un flux
81+
82+Il y a quelques limitations concernant les types **TReader**/**TWriter** qui peuvent être stockés dans un flux :
83+
84+- Les types de base sont admis pour un flux : string, integer, char, single, double, extended, byte, word, cardinal, shortint, les pointeurs de méthode, etc. ;
85+- **TPersistent** et ses descendants sont aussi admis pour un flux ;
86+- Les enregistrements (**records**), les objets et les classes ne descendant pas de **TPersistent** ne peuvent pas être stockés dans un flux . Pour les stocker dans un flux, vous devez surcharger certaines méthodes de **TReader**/**TWriter**. Voir ci-dessous Mise en flux de données courantes - DefineProperties.
87+
88+## Mise en flux de données courantes - DefineProperties.
89+
90+Vous pouvez mettre en flux des données arbitraires additionnelles en écrasant **DefineProperties**. Ceci permet de mettre en flux toutes les données qui n'ont aucun type de base. Par exemple, pour mettre en flux une variable **FMyRect: TRect** de votre composant , ajoutez les trois méthodes suivantes à votre composant :
91+
92+ procedure DefineProperties(Filer: TFiler); override;
93+ procedure ReadMyRect(Reader: TReader);
94+ procedure WriteMyRect(Writer: TWriter);
95+
96+avec le code suivant :
97+
98+ procedure TMyComponent.DefineProperties(Filer: TFiler);
99+ var
100+ MyRectMustBeSaved: Boolean;
101+ begin
102+ inherited DefineProperties(Filer);
103+ MyRectMustBeSaved:=(MyRect.Left<>0)
104+ or (MyRect.Top<>0)
105+ or (MyRect.Right<>0)
106+ or (MyRect.Bottom<>0);
107+ Filer.DefineProperty('MyRect',@ReadMyRect,@WriteMyRect,MyRectMustBeSaved);
108+ end;
109+
110+ procedure TMyComponent.ReadMyRect(Reader: TReader);
111+ begin
112+ with Reader do begin
113+ ReadListBegin;
114+ FMyRect.Left:=ReadInteger;
115+ FMyRect.Top:=ReadInteger;
116+ FMyRect.Right:=ReadInteger;
117+ FMyRect.Bottom:=ReadInteger;
118+ ReadListEnd;
119+ end;
120+ end;
121+
122+ procedure TMyComponent.WriteMyRect(Writer: TWriter);
123+ begin
124+ with Writer do begin
125+ WriteListBegin;
126+ WriteInteger(FMyRect.Left);
127+ WriteInteger(FMyRect.Top);
128+ WriteInteger(FMyRect.Right);
129+ WriteInteger(FMyRect.Bottom);
130+ WriteListEnd;
131+ end;
132+ end;
133+
134+Cela sauvegardera **MyRect** en tant que propriété **MyRect**.
135+
136+Si vous mettez en flux beaucoup de **TRect**, vous ne voudrez probablement pas écrire ce code chaque fois. L'unité **LResources** contient un exemple qui montre comment écrire une procédure pour définir une propriété **rect** :
137+
138+` procedure DefineRectProperty(Filer: TFiler; const Name: string; ARect, DefaultRect: PRect);`\
139+` `
140+
141+De cette façon, le code ci-dessus peut être réduit à :
142+
143+ procedure TMyComponent.DefineProperties(Filer: TFiler);
144+ begin
145+ inherited DefineProperties(Filer);
146+ DefineRectProperty(Filer,'MyRect',@FMyRect,nil);
147+ end;
148+
149+## Écrire votre propre composant - Partie 2
150+
151+L'exemple décrit peut être étendu. Ainsi, nous pouvons employer des propriétés arbitraires avec seulement quelques lignes de code :
152+
153+ type
154+ TMyComponent = class(TComponent)
155+ private
156+ FID: integer;
157+ FRect1: TRect;
158+ FRect2: TRect;
159+ protected
160+ procedure DefineProperties(Filer: TFiler); override;
161+ public
162+ property Rect1: TRect read FRect1 write FRect1;
163+ property Rect2: TRect read FRect2 write FRect2;
164+ published
165+ property ID: integer read FID write FID;
166+ end;
167+
168+ procedure TMyComponent.DefineProperties(Filer: TFiler);
169+ begin
170+ inherited DefineProperties(Filer);
171+ DefineRectProperty(Filer,'Rect1',@FRect1,nil);
172+ DefineRectProperty(Filer,'Rect2',@FRect2,nil);
173+ end;
174+
175+Ce composant peut maintenant être sauvegardé, chargé ou utilisé par [[RTTI controls/fr|Les contrôles RTTI]]. Vous n'avez pas besoin d'écrire quoi que ce soit d'autre.
176+
177+## Écrire et lire des composants depuis/vers LFM
178+
179+Consultez les fonctions **ReadComponentFromTextStream** et **WriteComponentAsTextToStream** de l'unité **lresources** pour des exemples.
180+
181+## Écrire et lire des composants depuis/vers XML
182+
183+Mettre en flux des composants est simple : Consultez l'exemple dans lazarus/examples/xmlstreaming/.
184+
185+## Noms
186+
187+- Tous les composants appartenant à un composant (**Owner**) doivent porter des noms distincts. Il en est de même pour deux fiches possédées par une application ou de deux étiquettes (**labels**) d'une fiche. Mais deux étiquettes appartenant à deux fiches distinctes peuvent porter le même nom et une fiche peut porter le même nom qu'un de ses enfants.
188+
189+- **TComponent.Name** peut rester vide et vous pouvez avoir plus d'un composant sans nom. **TWriter** écrira la propriété, mais **TReader** ne trouvera pas le composant en question si bien que la lecture échouera. Par conséquent, l'inspecteur d'objet de l'EDI ne tolère pas cette situation.
190+
191+- Les noms doivent être des identificateurs Pascal corrects ([IsValidIdent](http://lazarus-ccr.sourceforge.net/docs/rtl/sysutils/isvalidident.html)).
192+
193+- Lors d'une référence à d'autres fiches, tous les composants racines (**forms**, **datamodules**, ...) référencés eux-mêmes par d'autres (**forms**, etc.) doivent porter des noms uniques. Ils n'ont pas besoin d'être possédés par l'application, mais le programmeur doit alors par lui-même vérifier que leurs noms sont uniques. Les fiches et les modules de données peuvent être retrouvés grâce à l'objet **Screen** dans lequel toutes les fiches et tous les modules de données s'enregistrent automatiquement..
194+
195+- Vous pouvez créer de nombreuses fiches portant le nom **Form1** (par exemple, grâce à **TForm1.Create(nil)**). Si une **Form2** fait référence à **Form1.OpenDialog**, la première **Form1** dans **Screen** sera utilisée.
196+
197+- Une fiche **Form1** et un cadre imbriqué peuvent posséder tous les deux un enfant **Label1**. Quand l'étiquette **Label1** sera référencée, ce sera de manière univoque pour la fiche entière, donc en incluant les cadres imbriqués. Il est par conséquent vivement recommandé de donner un nom unique à chaque élément.
198+
199+- Correction globale : **TReader** lit le flux d'un composant. S'il rencontre un cadre imbriqué, un second **TReader** est créé afin d'en lire le flux. Ensuite, le lecteur retourne à son point de départ et continue la lecture. Les référence à d'autres composants (par exemple **Form1.Button1**) sont enregistrées dans une liste de correction dans les classes des unités (Voir [GetFixupReferenceNames](http://lazarus-ccr.sourceforge.net/docs/rtl/classes/getfixupreferencenames.html)). Les références sont rectifiées après la lecture.
200+
201+- **TReader** et **TWriter** utilisent le nom spécial **Owner** pour se référer au propriétaire en cours.
202+
203+## Conclusion
204+
205+La RTTI est un mécanisme puissant qui peut être employé pour facilement mettre en flux des classes entières et qui évite d'écrire beaucoup de code de chargement/enregistrement pénible.
206+
207+Voir également :
208+
209+[[RTTI controls/fr|Les contrôles RTTI]]
210+
211+---
212+*From the Free Pascal wiki, page "Streaming components/fr", as it stood on 2017-05-30 after a change by Gillou58, out of the wiki's dump of 2024-05-26. Copyright stays with the author who wrote it, according to the old wiki's [[Licensing]] page. If you have concerns about this material, [message the admin](/wiki-contact).*

Back to history