Sign in Join
Wiki copytemporary

mysql/fr: what changed

Revision 0 to 1. Removed lines have a minus sign; added lines have a plus sign.

Title: mysql/fr

OldNewLine
1+# Vue d'ensemble
2+
3+Vous pouvez utiliser Free Pascal/Lazarus pour accéder à un serveur de base de données MySQL. Aussi vous pouvez utiliser les composant MySQL Data Access (MyDAC) comme un composant pour connecter Lazarus à MySQL. Les [composants Lazarus MyDAC](https://www.devart.com/mydac/download.html) sont libres en téléchargement.
4+
5+Win64: veuillez lire les avertissements [[Windows Programming Tips/fr|ici]] sur l'inadéquation de certaines versions Win64 de FPC/Lazarus.
6+
7+Avantages de MySQL:
8+
9+- Il est très largement utilisé et disponible.
10+- Bien que les plus anciennes versions avaient la réputation de ne pas être de vrais SGBDR, les nouvelles versions prennent en charge les propriétés ACID si correctement configurées (avec le bon stockage en arrière plan (*backend storage*))
11+
12+Inconvénients de MySQL:
13+
14+- Les mainteneurs de MySQL ne conservent pas la compatibilité entre les versions de bibliothèque client. Ce qui signifie que la traduction en FPC/Lazarus doit être faite pour chaque nouvelle version, ce qui ralentit les choses.
15+- La licence peut être restrictive pour certaines utilisations (p.ex. les déploiements commerciaux). Il existe une alternative comme MariaDB compatible et sasn doute moins restrictive.
16+
17+De nombreux utilisateurs de Lazarus/FPC préfèrent les SGBDR [[Firebird/fr|Firebird]] ou [[postgres/fr|PostgreSQL]] pour cette raison.
18+
19+# Licence de MySQL
20+
21+Avant un déploiement significatif de MySQL, n'oubliez pas de lire sa [licence](https://www.mysql.com/about/legal/licensing/oem/).
22+
23+# SQLDB
24+
25+Lazarus 1.2 (with FPC 2.6.2), supports
26+
27+- Bibliothèque cliente MySQL 4.0
28+- Bibliothèque cliente MySQL 4.1
29+- Bibliothèque cliente MySQL 5.0
30+- Bibliothèque cliente MySQL 5.1
31+- Bibliothèque cliente MySQL 5.5 (pris en charge depuis Lazarus 1.0.8)
32+- Bibliothèque cliente MySQL 5.6 (pris en charge depuis Lazarus \<à remplir\>)
33+
34+![](/wiki-images/c/c5/Sqldbcomponents.png%E2%80%8E)
35+
36+De plus récentes versions de FPC/Lazarus peuvent supporter de plus récentes bibliothèques clientes de MySQL.
37+
38+Assurez-vous que vous utilisez le composant de connexion correct pour votre version de bibliothèque **client**. Ainsi si vous avez les bibliothèques clientes installées pour MySQL 4.1, vous devez utiliser le composant TMySQL41Connection, **même si le serveur fonctionne** en version 4.0 ou 5.0. La raison à cela est que les bibliothèques clientes MySQL casse souvent la compatibilité de leurs API et donc chaque version demande un pilote Pascal différent.
39+
40+Sur les systèmes *nix, le code SQLdb peut rechercher la version pure de la bibliothèque sans suffixe de numéro de version. Il y a plusieurs manières de pouvoir traiter ceci :
41+
42+- (sur plusieurs Linux) installer la version -dev de la bibliothèque.
43+- créer un lien symbolique sur le nom de bibliothèque spécifique vers celui que recherche FPC (plutôt que hacker)
44+- utiliser [[TSQLDBLibraryLoader/fr|TSQLDBLibraryLoader]] pour spécifier le nom de bibliothèque avant le chargement de la connexion.
45+
46+# Tutoriels SQLDB et exemple de code
47+
48+## Faire fonctionner MySQL dans Linux ou Windows
49+
50+Suivez les instructions dans le Manuel Utilisateur de MySQL. Assurez-vous que le daemon mysqld tourne de manière fiable, que tous les utilisateurs potentiels (y compris root, mysql, vous-mêmes et quiconque en aurait besoin) aient les priilèges qu'ils exigent, de n'importe quel hôte qu'il y a besoin (tel que 'localhost', le nom d'hôte local, et d'autres hôte sur votre réseau) tout en restant cohérent avec la sécurité. Il est préférable que les tous les utilisateurs, y compris le root, (NdT : sic) aient des mots de passe. Testez l'action du système de base de donnée en utilisant les exemples donnés dans le manuel et contrôlez que tous les utilisateurs ont des accès fiables.
51+
52+## Faire fonctionner MySQL avec FPC en mode texte
53+
54+Il y a un répertoire avec un programme d'exemple dans \$(fpcsrcdir)/packages/base/mysql/. Vous pouvez trouver le répertoire des sources dans Lazarus: Tools -\> Options -\> Files -\> FPC source directory. Les chemins possibles pour le répertoire mysql sont /usr/share/fpcsrc/packages/base/mysql/ (installation par rpm) ou C:\lazarus\fpcsrc\packages\base\mysql\\ (windows). Ce répertoire contient aussi les unités mysql.pp, mysql_com.pp et mysql_version.pp. Avant d'exécuter le script de test, vous avez besoin une base de données nommée testdb: faites ceci en vous connectant au moniteur mysql (en root avec tous les privilèges) et lancer les ordres SQL suivants :
55+
56+``` sql
57+CREATE DATABASE testdb;
58+```
59+
60+puis assurez-vous que tous les utilisateurs concernés ont les privilèges d'accès appropriés pour cela :
61+
62+``` sql
63+GRANT ALL ON testdb TO johnny-user IDENTIFIED BY 'johnnyspassword';
64+```
65+
66+Il y a un script appelé mkdb que vous devriez maintenant essayer de lancer :
67+
68+`sh ./mkdb`
69+
70+Cela échouera probablement, car le système ne permet pas à un utilisateur anonyme d'accéder à la base de données. Il faut donc changer le script en utilisant un éditeur à la ligne :
71+
72+`mysql -u root -p  ${1-testdb} << EOF >/dev/null`
73+
74+et essayez d'exécuter à nouveau en entrant votre mot de passe à l'invite. Avec de la chance, vous avez peut-être réussi à créer la base de données de test : testez-la (tant que vous être connectés dans le moniteur mysql) en lançant l'ordre mysql
75+
76+``` sql
77+select * from FPdev;
78+```
79+
80+Vous devriez voir une table listant l'ID, le nom d'utilisateur et l'adresse e-mail de quelques développeurs FPC. Maintenant, essayer d'exécuter le programme de test testdb.pp (il peut avoir besoin d'être compilé, et échouera certainement au premier essai !!).
81+
82+J'ai trouvé que le programme ne pourrait pas se connecter à mysql pourt plusieurs raisons :
83+
84+- Mon système (SuSE Linux v9.0) installe mysql v4.0.15, pas la version 3 pour laquelle le paquet a été conçu.
85+
86+- Le programme a besoin d'avoir les noms d'utilisateur et les mots de passe pour obtenir l'accès à la base de données.
87+
88+- Le compilateur demande à savoir où trouver les bibliothèques mysql (SI VOUS N'AVEZ PAS INSTALLER LES BIBLIOTHEQUES DE DEV, FAITES-LE MAINTENANT !)
89+
90+J'ai créé une copie de testdb.pp appelée trydb.pp, plutôt qu'éditer l'original - cela veut dire que les fichiers originaux peuvent encore être corrigés par les mise à jour de CVS. J'ai aussi copié les fichiers trouvés dans le sous-répertoire mysql/ver40/ dans le sous-répertoire mysql/, en les renommant mysql_v4.pp, mysql_com_v4.pp et mysql_version_v4.pp, en adaptant les nomes d'unités dans chacun des fichiers en conséquence. J'ai changé l'instruction uses dans trydb.pp en
91+
92+``` pascal
93+uses mysql_v4
94+```
95+
96+et l'instruction dans mysql_v4.pp en
97+
98+``` pascal
99+uses mysql_com_v4
100+```
101+
102+J'ai ajouté une ligne à /etc/fpc.cfg pour pointer vers mes bibliothèques :
103+
104+`-Fl/lib;/usr/lib`
105+
106+L'étape suivante pourrait être moins nécessaire si les bibliothèques de dév. sont installées car les liens sont installés pour vous, mais cela ne coûte rien de vérifier. J'ai dû trouvé le vrai nom de la bibliothèque cliente de mysql dans le répertoire /usr/lib et dans mon cas j'ai dû lancer la commande shell :
107+
108+`ln -s libmysqlclient.so.12.0.0 lmysqlclient`
109+
110+pour faire un lien symbolique permettant à FPC de trouver la bibliothèque. Pour faire bonne mesure, j'ai aussi créé le lien :
111+
112+`ln -s libmysqlclient.so.12.0.0 mysqlclient`
113+
114+et placé des liens similaires dans divers autres répertoires : pas strictement nécessaire, mais juste au cas où ... ! Certains utilisateurs pourraient avoir besoin d'ajouter le lien suivant :
115+
116+`ln -s libmysqlclient.so.12.0.0 libmysqlclient.so`
117+
118+J'ai modifié trydb.pp pour inclure les détails utilisateur, initialement en ajoutant l'hôte, l'utilisateur et le mot de passe en constantes :
119+
120+``` pascal
121+const
122+ host : Pchar= 'localhost';
123+ user : Pchar= 'myusername';
124+ passwd: Pchar = 'mypassword';
125+```
126+
127+> **Warning:** Cette section semble extrêmement obsolète. Si vous êtes encore sur MySQL 4 peut-être est-il temps de vous mettre à jour.
128+
129+J'ai aussi trouvé que je ne pouvais pas me connecter à mysql en utilisant l'appel à mysql_connect(),mais devais utiliser mysql_real_connect() qui a plusieurs paramètres. Pour compliquer un peu plus les choses, le nombre de paramètres semble avoir été changé entre la version 3 (où il y en a sept) et la version 4 (où il y en a huit). Avant d'utiliser mysql_real_connect j'ai dû utiliser mysql_init() lequel n'est pas trouvé dans le mysql.pp original mais est trouvé dans mysql_v4.pp.
130+
131+Donc le code pour la connexion à la base de données est maintenant :
132+
133+``` pascal
134+{ a few extra variables}
135+var
136+ alloc : PMYSQL;
137+
138+{main program fragment}
139+
140+begin
141+ if paramcount=1 then
142+ begin
143+ Dummy:=Paramstr(1)+#0;
144+ DataBase:=@Dummy[1];
145+ end;
146+
147+ Writeln('Allocating Space...');
148+ alloc := mysql_init(PMYSQL(@qmysql));
149+ Write('Connecting to MySQL...');
150+ sock := mysql_real_connect(alloc, host, user, passwd, database, 0, nil, 0);
151+ if sock=Nil then
152+ begin
153+ Writeln(stderr,'Couldn''t connect to MySQL.');
154+ Writeln(stderr, 'Error was: ', mysql_error(@qmysql));
155+ halt(1);
156+ end;
157+ Writeln('Done.');
158+ Writeln('Connection data:');
159+ {$ifdef Unix}
160+ writeln('Mysql_port : ',mysql_port);
161+ writeln('Mysql_unix_port : ',mysql_unix_port);
162+ {$endif}
163+ writeln('Host info : ',mysql_get_host_info(sock));
164+ writeln('Server info : ',mysql_stat(sock));
165+ writeln('Client info : ',mysql_get_client_info);
166+
167+ Writeln('Selecting Database ',DataBase,'...');
168+ if mysql_select_db(sock, DataBase) < 0 then
169+ begin
170+ Writeln(stderr,'Couldn''t select database ',Database);
171+ Writeln(stderr,mysql_error(sock));
172+ halt(1);
173+ end;
174+ {... as original contents of testdb.pp}
175+```
176+
177+Maintenant - prêt pour démarrer le compilation de trydb.pp ?
178+
179+` fpc trydb`
180+
181+Réussite ! Vous opouvez dorénavant l'exécuter :
182+
183+` ./trydb`
184+
185+Youpi ! J'ai eu le listing des développeurs FPC !
186+
187+Un petit raffinement supplémentaire : Rendre l'entrée des détails de l'utilisateur et les commandes mysql interactives, utiliser des variables plutôt que des constantes et permettre l'entrée de plusieurs commandes SQL, jusqu'à ce que nous émettions la commande quit : voir [[Lazarus Database Tutorial/TryDbpp|liste complète des programmes]], où les détails de l'utilisateur sont entrés dans la console, et le programme passe dans une boucle où les commandes SQL sont entrées depuis la console (sans le point-virgule terminal) et les réponses sont imprimées, jusqu'à ce que "quit" soit saisi à partir du clavier.
188+
189+Voir [[Lazarus Database Tutorial/SampleListing|Exemple de listing console]].
190+
191+## Se connecter à MySQL depuis une application Lazarus
192+
193+Ce tutoriel montre comment connecter Lazarus à une base de données MySQL, et exécute de simples requêtes, en utilisant les composants Lazarus de base ; il utilise aucun composant sensible aux données, mais illustre les principes d'interaction avec la base de données.
194+
195+Créez un nouveau projet dans Lazarus :
196+
197+`Project -> New Project -> Application`
198+
199+Une nouvelle forme automatiquement générée apparaîtra.
200+
201+Agrandissez la fiche à environ la moitié de l'écran, ensuite renommez la fiche et sa légende (*caption*) en 'TryMySQL'.
202+
203+Depuis l'onglet Standard de la palette de composant, placez trois TEdit en haut à gauche de la fiche et immédiatement en dessus de chaque TEdit placez une étiquette (*Label*). Changez les noms et les légendes en 'Hôte' (avec HostLLabel, HostEdit), 'Nom d'utilisateur' (avec UserLabel, UserEdit) et 'Mot de passe' (avec PasswdLabel et PasswdEdit). De manière alternative; vous pourriez utiliser des composants LabelledEdit depuis l'onglet Additional.
204+
205+Sélectionnez le champ de saisie Mot de passe et trouvez la propriété PasswordChar : changez-la en '*' ou quelque autre caractère, ce qui empêchera les caractères saisis d'apparaître à l'écran, ce caractère apparaîtra à la place. Assurez-vous que les propriétés Text sont à blanc.
206+
207+Maintenant placez une autre zone de saisie TEdit et une étiquette (TLabel) en haut du côté droit de votre fiche. Changez l'étiquette en 'Entrez un ordre SQL'. et nommez-le CommandEdit.
208+
209+Placez trois boutons sur la fiche : deux sur la gauche sous les champs de saisie et un à droite sous la zone Ordre.
210+
211+Changez les légendes des boutons de gauche en 'Se connecter' (ConnectButton) et 'Terminer' (ExitButton) et pour celui à droite 'Envoyer la requête' (QueryButton).
212+
213+Placez un TMemo large étiqueté et nommé 'Résultats' (ResultMemo) dans le bas à droite, de façon à remplir au mieux la place libre. Trouvez la propriété ScrollBars et sélectionnez ssAutoBoth, ainsi les barres de défilement apparaîtront automatiquement si l le texte remplit l'espace. Définissez la propriété WordWrap à True.
214+
215+Placez une barre de status (depuis l'onglet Contrôles Communs) tout en bas de la fiche et et mettre dans sa propriété SimpleText 'TryMySQL'.
216+
217+Une capture d'écran de la fiche peut être vue ici : [Exemple Mysql](http://lazarus-ccr.sourceforge.net/kbdata/trymysqldb.png).
218+
219+Maintenant vous devez coder quelques gestionnaires d'événement.
220+
221+Les trois boîtes d'édition sur la gauche sont des entrées pour le nom d'hôte, le nom d'utilisateur et le mot de passe. Quand elles sont entrées de manière satisfaisante, le bouton Connect est cliqué. Le gestionnaire OnClick de ce bouton est basé en partie sur la programme en mode texte du dessus.
222+
223+Les réponses de la base de données devraient être converties en chaînes et affichées dans le mémo. Les procédures Pascal en mode texte Write et WriteLn sont capables de faire beaucoup de conversions 'en vol', mais l'utilisation de la boîte Mémo pour la sortie de texte nécessite une conversion explicite de types de donnée vers la chaîne correcte : donc les variables PChar doivent être converties en chaînes en utilisant StrPas et les entiers doivent être convertis avec IntToStr . Les chaînes sont affichées dans le Mémo en utilisant :
224+
225+``` pascal
226+procedure ShowString(S : string);
227+(* display a string in a Memo box *)
228+begin
229+ trymysqlForm1.ResultsMemo.Lines.Add(S)
230+end;
231+```
232+
233+Le gestionnaire de l'événément du ConnectButton devient alors :
234+
235+``` pascal
236+procedure TtrymysqlForm1.ConnectButtonClick(Sender: TObject);
237+(* Connect to MySQL using user data from Text entry boxes on Main Form *)
238+var strg: string;
239+
240+begin
241+ dummy1 := trymysqlForm1.HostEdit.text+#0;
242+ host := @dummy1[1];
243+ dummy2 := trymysqlForm1.UserEdit.text+#0;
244+ user := @dummy2[1] ;
245+ dummy3 := trymysqlForm1.PasswdEdit.text+#0;
246+ passwd := @dummy3[1] ;
247+
248+ alloc := mysql_init(PMYSQL(@qmysql));
249+ sock := mysql_real_connect(alloc, host, user, passwd, database, 0, nil, 0);
250+ if sock=Nil then
251+ begin
252+ strg :='Couldn''t connect to MySQL.'; showstring (strg);
253+ Strg :='Error was: '+ StrPas(mysql_error(@qmysql)); showstring (strg);
254+ end
255+ else
256+ begin
257+ trymysqlForm1.statusBar1.simpletext := 'Connected to MySQL';
258+ strg := 'Now choosing database : ' + database; showstring (strg);
259+ {$ifdef Unix}
260+ strg :='Mysql_port : '+ IntToStr(mysql_port); showstring (strg);
261+ strg :='Mysql_unix_port : ' + StrPas(mysql_unix_port); showstring (strg);
262+ {$endif}
263+ Strg :='Host info : ' + StrPas(mysql_get_host_info(sock));
264+ showstring (strg);
265+ Strg :='Server info : ' + StrPas(mysql_stat(sock)); showstring (strg);
266+ Strg :='Client info : ' + Strpas(mysql_get_client_info); showstring (strg);
267+
268+ trymysqlForm1.statusbar1.simpletext := 'Selecting Database ' + DataBase +'...';
269+ if mysql_select_db(sock,DataBase) < 0 then
270+ begin
271+ strg :='Couldn''t select database '+ Database; ShowString (strg);
272+ Strg := mysql_error(sock); ShowString (strg);
273+ end
274+ end;
275+end;
276+```
277+
278+La zone de texte sur la droite permet d'entrer un ordre SQL, sans le point-virgule final ; quand vous êtes satisfait du contenu ou de sa syntaxe, le bouton SendQuery est enfoncé et la requête exécutée, avec ses résultats écrits dans le mémo ResultsMemo.
279+
280+Le gestionnaire d'événement de SendQuery est à nouveau basé sur la version en mode texte de FPC, sauf que, une fois de plus, la conversion de type explicite doit être effectuée avant que les chaînes ne soient affichées dans la boîte.
281+
282+La différence avec la version en mode texte est que si une condition d'erreur est détectée, le programme ne s'arrête pas et MySQL n'est pas fermé ; au lieu de cela, le contrôle est rendu à la fiche principale et il devient possible de corriger l'entrée avant de soumettre à nouveau l'ordre SQL. L'application se termine enfin (avec la fermeture de MySQL) quand le bouton Exit est cliqué.
283+
284+Le code de SendQuery est le suivant :
285+
286+``` pascal
287+procedure TtrymysqlForm1.QueryButtonClick(Sender: TObject);
288+var
289+ dumquery, strg: string;
290+begin
291+ dumquery := TrymysqlForm1.CommandEdit.text;
292+ dumquery := dumquery+#0;
293+ query := @dumquery[1];
294+ trymysqlForm1.statusbar1.simpletext := 'Executing query : '+ dumQuery +'...';
295+ strg := 'Executing query : ' + dumQuery; showstring (strg);
296+ if (mysql_query(sock,Query) < 0) then
297+ begin
298+ Strg :='Query failed '+ StrPas(mysql_error(sock)); showstring (strg);
299+ end
300+ else
301+ begin
302+ recbuf := mysql_store_result(sock);
303+ if RecBuf=Nil then
304+ begin
305+ Strg :='Query returned nil result.'; showstring (strg);
306+ end
307+ else
308+ begin
309+ strg :='Number of records returned : ' + IntToStr(mysql_num_rows (recbuf));
310+ Showstring (strg);
311+ Strg :='Number of fields per record : ' + IntToStr(mysql_num_fields(recbuf));
312+ showstring (strg);
313+ rowbuf := mysql_fetch_row(recbuf);
314+ while (rowbuf <>nil) do
315+ begin
316+ Strg :='(Id: '+ rowbuf[0]+', Name: ' + rowbuf[1]+ ', Email : ' +
317+ rowbuf[2] +')';
318+ showstring(strg);
319+ rowbuf := mysql_fetch_row(recbuf);
320+ end;
321+ end;
322+ end;
323+end;
324+```
325+
326+Enregistrez votre projet et exécutez (menu Run -\> Run).
327+
328+### Télécharger le code source de l'exemple
329+
330+> **Warning:** Les versions actuelles de Lazarus/FPC demande de valider toutes les transactions MySQL. Ceci n'était pas nécessaire dans les version précédentes. Le code téléchargé ne tournera certainement pas tant qu'il ne sera pas mis à jour.
331+
332+Un listing complet du programme est disponible ici [Sample Source Code](http://sourceforge.net/projects/lazarus-ccr/files/Demos%20and%20examples/MySql%20demo%20using%20SQLdb%20components%208%20April%202005/mysql_demo_20050408.tar.gz/download).
333+
334+## Lazarus, MySQL et UTF-8
335+
336+*Ce qui suit peut être aussi bien nécessaire pour d'autres pages de code/jeux de caractères.*
337+
338+L'Unicode UTF-8 est un encodage de jeu de caractères multi-octet commode, qui permet de travailler avec des textes multilingues sans demander de WideStrings (2 octets par caratère). Il est supporté aussi bien par les composants SQLdb Lazarus que par MySQL depuis la version 4.1 en choisissant le jeu de caractères approprié.
339+
340+Néanmoins, en réglant simplement cet encodage comme défaut pour
341+
342+- vos tables et
343+- le composant de connexion MySQL (p.ex. `TMySQL51Connection.CharSet:='UTF8';`)
344+
345+aboutira à un stockage et à la récupération de chaînes UTF-8 incorrects : tout caractères accentués/international sera montré avec des point d'interrogation (?). Apparemment, la raison à cela est que la bibliothèque client est compilée pour s'attendre à des caractère Latin1 défini par défaut.
346+
347+En vue d'une communication correcte entre Lazarus, la bibliothèque client MySQL et le serveur MySQL, dexu requêtes supplémentaires demandes à être exécutées *à chaque fois* qu'une connexion à la bse de données est établie :
348+
349+``` sql
350+SET CHARACTER SET `utf8`
351+```
352+
353+et
354+
355+``` sql
356+SET NAMES 'utf8'
357+```
358+
359+La première requête s'assurera que votre application reçoive des chaînes correctement encodées, et la seconde demande à MtySQL de ne pas convertir les chaînes qu'il reçoit de votre application.
360+
361+## Simple démo MySQL utilisant le composant TMySQL5xConnection
362+
363+Voici du code qui fonctionne comme une démo vite fait pour démarrer et s'exécuter simplement. Comme avec tous les composants SQLdb, assurez-vos que la bibliothèque client est à l'emplacement correct :
364+
365+- dans Windows: la DLL p.ex. libmysql.dll est mise dans dossier de sortie du projet (où l'exécutable est généré). Vous pouvez aussi la placer dans votre répertoire Windows/system32.
366+- dans Linux/OSX: installez la bibliothèque client de MySQL dans votre chemin (p.ex. en utilisant votre gestionnaire de paquet, rpm, deb...).
367+
368+Lors de la distribution de votre application, assurez-vous que la bonne bibliothèque client de MySQL est présente sur l'ordinateur de votre utilisateur. Comme cela peut être un problème, peut-être qu'utiliser un moteur de base de données différent peut être plus pertinent.
369+
370+## Exemple conduit par le code
371+
372+Cet exemple utilise du code pour remplir des contrôles avec de la donnée. Vous pouvez aussi utiliser des contrôles sensibles aux données (TDBEdit...), ce qui pourrait être plus facile/rapide. Voir l'exemple du dessous ou le [[SQLdb Tutorial1/fr|Tutoriel SQLdb 1]] pour cela.
373+
374+Placez trois champs d'édition (TEdit), un champ Mémo et quelques boutons sur la fiche. Vous devez ajoutez mysqlXXconn and sqldb dans la clause Uses.
375+
376+Dans cet exemple, le SGBD MySQL a un utilisateur 'root' sans mot de passe et une base de données 'test1' avec une table 'tPerson' qui a trois champs : 'personid' (int), 'surname' (varchar(40)) et 'dob' (datetime). Aussi quelques données de test ont été ajoutées.
377+
378+Le bouton btnTest doit être cliqué en premier car il crée la connexion avec le, SGBD. Notez la ligne qui applique les mises à jour - sans cela, les données modifiées ou nouvelles ne seront pas retournées au DB même si elles seront en mémoire et peuvent être visualisées à l'aide de btnFirst et btnNext.
379+
380+``` pascal
381+unit unt_db;
382+// Example based on:
383+// http://www.lazarus.freepascal.org/index.php?name=PNphpBB2&file=viewtopic&t=5761
384+// from tpglemur on that forum
385+{$mode objfpc}{$H+}
386+interface
387+uses
388+ Classes, SysUtils, LResources, Forms, Controls, Graphics, Dialogs,
389+ mysql50conn, sqldb, StdCtrls;
390+type
391+ { TForm1 }
392+ TForm1 = class(TForm)
393+ btnTest: TButton;
394+ btnNext: TButton;
395+ btnFirst: TButton;
396+ btnNew: TButton;
397+ edtPersonID: TEdit;
398+ edtSurname: TEdit;
399+ edtDOB: TEdit;
400+ Memo1: TMemo;
401+ procedure btnFirstClick(Sender: TObject);
402+ procedure btnNewClick(Sender: TObject);
403+ procedure btnNextClick(Sender: TObject);
404+ procedure btnTestClick(Sender: TObject);
405+ private
406+ { private declarations }
407+ conn : TMySQL50Connection;
408+ query : TSQLQuery;
409+ transaction : TSQLTransaction;
410+ procedure Display;
411+ public
412+ { public declarations }
413+ end;
414+var
415+ Form1: TForm1;
416+implementation
417+{ TForm1 }
418+procedure TForm1.btnTestClick(Sender: TObject);
419+var
420+ S: String;
421+begin
422+ conn := TMySQL50Connection.Create(nil);
423+ query := TSQLQuery.Create(nil);
424+ transaction := TSQLTransaction.Create(nil);
425+ try
426+ try
427+ // Adjust to your own database server, username and password:
428+ conn.HostName := '127.0.0.1';
429+ conn.UserName := 'root';
430+ conn.Password := '';
431+ // If you use a different database name, adjust here:
432+ conn.DatabaseName := 'test1';
433+ conn.Connected := True;
434+ conn.Transaction := transaction;
435+ query.DataBase := conn;
436+ //query.ParseSQL := true; //line not needed - this is the default anyway
437+ //query.ReadOnly := false; //line not needed - this is the default anyway
438+ query.SQL.Text := 'select * from tperson';
439+ query.Open;
440+
441+ query.Last;
442+ S := IntToStr(query.RecordCount) + #13#10;
443+ query.First;
444+
445+ while not query.EOF do
446+ begin
447+ S := S + query.FieldByName('surname').AsString + #13#10;
448+ query.Next;
449+ end;
450+ finally
451+ //query.Free;
452+ //conn.Free;
453+ end;
454+ except
455+ on E: Exception do
456+ ShowMessage(E.message);
457+ end;
458+ Memo1.Text:= S;
459+end;
460+
461+procedure TForm1.Display;
462+begin
463+ edtPersonID.Text := query.FieldByName('personid').AsString;
464+ edtSurname.Text := query.FieldByName('surname').AsString;
465+ edtDOB.Text := query.FieldByName('dob').AsString;
466+end;
467+
468+procedure TForm1.btnFirstClick(Sender: TObject);
469+begin
470+ query.First;
471+ Display;
472+end;
473+
474+procedure TForm1.btnNewClick(Sender: TObject);
475+begin
476+ query.Append;
477+ query.FieldValues['personid'] := edtPersonID.Text;
478+ query.FieldValues['surname'] := edtSurname.Text;
479+ query.FieldValues['dob'] := edtDOB.Text;
480+ query.Post;
481+ query.ApplyUpdates; //to apply update
482+ transaction.Commit; //Needed since FPC 2.6.4; todo: somebody should check if this is enough
483+end;
484+
485+procedure TForm1.btnNextClick(Sender: TObject);
486+begin
487+ query.Next;
488+ Display;
489+end;
490+
491+initialization
492+ {$I unt_db.lrs}
493+end.
494+```
495+
496+## RAD/Contrôles liés aux données
497+
498+Veuillez voir [[SQLdb Tutorial1/fr|Tutoriel SQLdb 1]], [[SQLdb Tutorial2/fr|Tutoriel SQLdb 2]] et plus de tutoriels.
499+
500+# Zeos
501+
502+Voir [[ZeosDBO/fr|ZeosDBO]]
503+
504+# Pascal Data Objects (PDO)
505+
506+Pascal Data Objects is an alternative data access layer that seems to support:
507+
508+- Clients MySQL 4.0
509+- Clients MySQL 4.1
510+- Clients MySQL 5.0
511+- (et aussi) Firebird 1.5 et 2.0
512+
513+Les fonctions introduites dans MySQL 4.1 et 5.0 comme les instructions préparées, la liaison et les procéduresstockées sont prises en charge. PDO est inspiré de PHP Data Objects. Tout le code et la documentation nécessaire à l'emploi de cette API est disponible sur [sourceforge](http://pdo.sourceforge.net).
514+
515+# Paquet MySQL : Les unités de bas-niveau
516+
517+Comme avec toute les bases de données, le code SQLdb dépend d'une unité spécifique à MySQL de bas niveau qui enveloppe la bibliothèque du pilote MySQL (.so/.dll). Normalement, vous utiliseriez le code SQLdb de haut niveau car il vous permet de coder plus rapidement, de changer plus facilement de SGBD, etc.
518+
519+Utiliser ceci est très facile, tout ce dont vous avez besoin est de compiler certaines unités, et d'utiliser ces unités dans votre programme. Vous avez besoin de spécifier l'emplacement dans le système de fichiers de la bibliothèque client MySQL (libmysqlclient sur Linux) lors de la compilation, et c'est tout.
520+
521+## Unités et programmes fournis
522+
523+Le paquet fournit 3 unités, desquelles seulement le première est nécessaire :
524+
525+- *mysql* la principale unité mysql.
526+- *mysql\<version\>* (p.ex. *mysql50*) fournit l'accès à une bibliothèque pour cette version. note : la version de la bibliothèque cliente n'est pas corrélée à celle du serveur en usage - sauf si vous voulez que ces versions soient compatibles.
527+- *mysql\<version\>com* contient quelques routines internes de MySQL (Vraisemblablement une traduction de mysql_com.h) ; elle ne devrait normalement pas être utilisée à moins que vous vouliez accéder à certains types internes.
528+
529+Des programmes d'exemple peuvent être trouvés dans le répertoire \<fpc\>\packages\mysql\examples.
530+
531+## Installation
532+
533+L'interface à MySQL est distribuée avec les paquets Free Pascal et est fourni avec la distribution du compilateur : normalement aucune action ne doit être entreprise pour travailler avec MySQL.
534+
535+Au cas où vous voulez modifier et compiler les unités vous-mêmes, le sources pour MySQL sont dans le répertoire des paquets : *packages/mysql*.
536+
537+Ce répertoire contient les unités, un programme de test et un fichier make. Placez-vous (commande cd) dans le répertoire et tapez :
538+
539+`make`
540+
541+Ceci devrait compiler les unités. Si la compilation est réussie, vous pouvez installer avec :
542+
543+`make install`
544+
545+Vous pouvez tester le programme en exécutant :
546+
547+`make test`
548+
549+Ceci aura pour effet :
550+
551+- d'exécuter un script pour créer une table dans la base de données et de la remplier avec quelques données. (le programme MySQL doit être accessible via la variable PATH pour cela). Par défaut, la base de données utilisée est 'testdb',
552+- d'exécuter le programme de test testdb,
553+- d'exécuter un nouveau shell pour supprimer la table créée.
554+
555+Vous verrez beaucoup de messages sur votre écran, vous donnant des retours d'information et des résultats. Si quelque chose n'a pas marché, make vous en informera.
556+
557+Retour à la [[Package List/fr|liste des paquets]].
558+
559+# Voir aussi
560+
561+- [[Lazarus DB Faq/fr|FAQ sur DB de Lazarus]] - Plus au sujet de la programmation des bases de données.
562+- [[SQLdb Tutorial1/fr|Tutoriel 1 sur SQLdb]] - Série de tutoriels sur SQLDB qui vous fait créé une base de données qui marche et une application IHM avec une grille.
563+- [[Lazarus Database Overview/fr|Vue d'ensemble des bases de données avec Lazarus]] - Faire en sorte que Lazare fonctionne avec diverses bases de données.
564+
565+---
566+*From the Free Pascal wiki, page "mysql/fr", as it stood on 2023-01-26 after a change by Slawek, out of the wiki's dump of 2024-05-26. Copyright stays with the author who wrote it, according to the old wiki's [[Licensing]] page. If you have concerns about this material, [message the admin](/wiki-contact).*

Back to history