macOS Find Default Application

(macOS only)

Overview

From time to time your application may need to determine the user's default application for opening certain content - for example, a web URL or a system file.

Example code which demonstrates how to do this is set out below. Note that these are obviously not the only two content for which you may wish to determine the user's default application, but the same general approach will apply for those other content types.

The alternative example code below demonstrates how to do this for various URL schemes (eg mailto:, http:, https:, sms:, tel:, etc).

Example code

pascal

unit Unit1;

{$mode objfpc}{$H+}
{$modeswitch objectivec2}

interface

uses
  Classes,
  Forms,
  Dialogs,    // needed for ShowMessage()
  StdCtrls,   // needed for buttons
  CocoaAll,   // needed for Cocoa framework (origin the NeXTSTEP libraries)
  CocoaUtils; // needed for NSStringToString()

type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private

  public

  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.Button1Click(Sender: TObject);
var
  contentUrl: NSUrl;
  defAppUrl: NSUrl;
  defAppName: String;
begin
  contentUrl := NSUrl.URLWithString(NSSTR('https://sentinel.sentry.org/'));
  defAppUrl := NSWorkspace.sharedWorkspace.URLForApplicationToOpenURL(contentUrl);

  // Bundle ID (required)
  ShowMessage(NSStringToString(NSBundle.bundleWithURL(defAppUrl).bundleIdentifier));

  // Bundle Display Name (optional)
  defAppName := NSStringToString(NSBundle.bundleWithURL(defAppUrl).objectForInfoDictionaryKey(NSStr('CFBundleDisplayName').description));
  // Bundle Name (conventionally required)
  if (defAppName = '') then
    defAppName := NSStringToString(NSBundle.bundleWithURL(defAppUrl).objectForInfoDictionaryKey(NSStr('CFBundleName').description));
  // Cannot fail :-)
  if (defAppName = '') then
    defAppName := NSStringToString(defAppUrl.URLByDeletingPathExtension.lastPathComponent);

  // Show result
  ShowMessage(defAppName);
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  contentUrl: NSUrl;
  defAppUrl: NSUrl;
  defAppName: String;
begin
  contentUrl := NSUrl.URLWithString(NSSTR('file:///Users/trev/my_defaults.txt'));
  defAppUrl := NSWorkspace.sharedWorkspace.URLForApplicationToOpenURL(contentUrl);

  // Bundle ID (required)
  ShowMessage(NSStringToString(NSBundle.bundleWithURL(defAppUrl).bundleIdentifier));

  // Bundle Display Name (optional)
  defAppName := NSStringToString(NSBundle.bundleWithURL(defAppUrl).objectForInfoDictionaryKey(NSStr('CFBundleDisplayName').description));
  // Bundle Name (conventionally required)
  if (defAppName = '') then
    defAppName := NSStringToString(NSBundle.bundleWithURL(defAppUrl).objectForInfoDictionaryKey(NSStr('CFBundleName').description));
  // Cannot fail :-)
  if (defAppName = '') then
    defAppName := NSStringToString(defAppUrl.URLByDeletingPathExtension.lastPathComponent);

  // Show result
  ShowMessage(defAppName);
end;

end.

Full project source code is available from SourceForge.

Alternative example code for URL schemes

Note that LSGetApplicationForURL was deprecated in macOS 10.10 (Yosemite) in favour of LSCopyDefaultApplicationURLForURL which itself was deprecated in macOS 12 (Monterey), both functions are still working in macOS 12.0.1. There is no example code for LSCopyDefaultApplicationURLForURL because the function is missing from the FPC packages/univint/src/LSInfo.pas file.

pascal

unit Unit1;

{$mode objfpc}{$H+}
{$modeswitch objectivec1}

interface

uses
  SysUtils, Forms, StdCtrls,
  MacOSAll, CocoaAll, CocoaUtils;

type

  { TForm1 }

  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
  private

  public

  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.Button1Click(Sender: TObject);
var
  myURL: NSURL;
  URLRef: CFURLRef;
  OSStatus: Integer;
  myStr: String;
begin
  // Create URL scheme from one of:
  // file:///
  // file://localhost/
  // mailto:
  // http:
  // https:
  // ftp:
  // sms:
  // tel:
  // facetime:
  // ... There are probably more.
  myURL := NSURL.alloc.initWithString(NSStr('mailto:'));

  // Check for default pplication
  OSStatus := LSGetApplicationForURL(CFURLRef(myURL), kLSRolesAll, Nil, @URLRef);

  // Check for error (eg application not found for URL = -10814)
  if(OSStatus <> 0) then
    begin
      Memo1.Append('LSGetApplicationForURL error status: ' + IntToStr(OSStatus));
      Exit;
    end;

  // Get CFString from CFURLRef, Cast to NSString, Convert to AnsiString
  myStr := NSStringToString(NSString(CFURLGetString(URLRef)));

  // Output to memo
  memo1.Append('LSGetApplicationForURL status: ' + IntToStr(OSStatus)
    + LineEnding + LineEnding + 'Default app: ' + myStr);

  // Housekeeping
  myURL.release;
end;

end.

Full project source code is available from SourceForge.

External links

Apple: NSWorkspace - available from macOS 10.0
Apple: NSURL - available from macOS 10.0
Apple: CFURL, CFURLRef - available from macOS 10.0
Apple: LSGetApplicationForURL - available from macOS 10.0 - deprecated in macOS 10.10
Apple: LSCopyDefaultApplicationURLForURL - available from macOS 10.10 - deprecated in macOS 12

From the Free Pascal wiki, page "macOS Find Default Application", as it stood on 2021-12-08 after a change by Alextp, out of the wiki's dump of 2024-05-26. Copyright stays with the author who wrote it, according to the old wiki's Licensing page. If you have concerns about this material, message the admin.

Revision 1, last changed by WikiArchive 11-4-2026.

Edited on wiki.freepascal.org by 2 people, 2020–2021

From the official wiki's backup of 26 May 2024: who edited this page there, and when. Edits made there after that date were not recorded, and the earlier versions are not shown here; the main page says why.

When	Who	What changed
12-31-2020	Trev	New macOS article
12-31-2020	Trev	Example code: Code tidy (minor)
12-31-2020	Trev	Example code: Code clarity (minor)
12-8-2021	Trev	Alternative example code for URL schemes: New section
12-8-2021	Trev	See also: New section
12-8-2021	Trev	External links: New section
12-8-2021	Trev	External links: Update link (minor)
12-8-2021	Trev	Alternative example code for URL schemes: Note deprecations
12-8-2021	Trev	External links: Add entry; qualify availability
12-8-2021	Trev	External links: Qualify availability
12-8-2021	Trev	Alternative example code for URL schemes: Note FPC missing function
12-8-2021	Trev	Example code: Add SourceForge link to project
12-8-2021	Trev	Alternative example code for URL schemes: Add SourceForge link
12-8-2021	Alextp	Overview

What readers said (1)

Talk about this page

Nobody has opened a bench for this page yet. Sign in to open one.