Database tutorial Zeos1/de

│ Deutsch (de) │

Zurück zu unserem Beispiel. Wir wollen alle Daten aus der Tabelle 'CUSTOMER' anzeigen. Der SQL Befehl dazu lautet:

select * from CUSTOMER

Diesen Befehl müssen wir der 'SQL' Eigenschaft von ZQuery1 zuweisen. Im Quelltext unseres Programms würde das so aussehen:

ZQuery1.SQL.Text��:= 'select * from CUSTOMER';

Wird der Befehl in Textform angegeben, dann muss er in einfache Anführungszeichen eingeschlossen werden. Man könnte natürlich auch den Inhalt einer anderen Komponente zuweisen.

Die Abfrage der Daten soll erfolgen, wenn der Benutzer auf den Button klickt. Mit einem Doppelklick auf Button1 erzeugt Lazarus das Grundgerüst der dafür notwendigen Prozedur. In ihrem Quelltext sollte jetzt folgendes stehen:

procedure TForm1.Button1Click(Sender: TObject);
    begin
    
    end;

Zwischen begin und end müssen wir jetzt die Anweisungen eingeben, die zum Anzeigen der Daten erforderlich sind. Die 'SQL' Eigenschaft von ZQuery1 kann nur geändert werden, wenn ZQuery1 nicht aktiv ist. Daher schließen wir die Komponente zunächst:

ZQuery1.Close;

Da wir nicht sicher sein können, ob ZQuery1 noch irgendwelche Daten enthält, rufen wir die 'Clear' Prozedur auf:

ZQuery1.SQl.Clear;

Dann weisen wir der 'SQL' Eigenschaft unsere SQL Anweisung zu:

ZQuery1.SQL.Text��:= 'select * from CUSTOMER';

Jetzt müssen wir die Verbindung zur Datenbank herstellen und dann die Abfrage öffnen:

ZConnection1.Connected��:= True;
    ZQuery1.Open;

Wenn sie jetzt ihr Programm kompilieren würden, dann würden die Daten aus der Tabelle 'CUSTOMER' bereits angezeigt werden. Ein ordentliches Programm wird aber spätestens beim Beenden dafür sorgen, dass noch offene Verbindungen zur Datenbank geschlossen werden. Die Nebenwirkungen wären sonst nicht absehbar. Wir verwenden das OnClose Ereignis unseres Formulars (mittels Doppelklick im Objektinspektor erzeugen):

procedure TForm1.FormClose(Sender: TObject; var CloseAction: TCloseAction);
    begin
    
    end;

Beim Trennen verwenden wir die umgekehrte Reihenfolge wie beim Verbinden:

ZQuery1.Close;
     ZConnection1.Connected := False;

Zusammenfassung

Wir haben bisher gelernt, wie man mit den Zeos-Komponenten eine Verbindung zu einer Firebird Datenbank herstellt und die Daten einer Tabelle am Bildschirm anzeigt.

Erweiterung von Beispiel 1

Wenn sie sich an die bisherigen Schritte gehalten haben, dann sollte ihr Quelltext etwa so aussehen:

unit Unit1;
    
    {$mode objfpc}{$H+}
    
    interface
    
    uses
      Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, DBGrids,
      StdCtrls, db, ZConnection, ZDataset;
    
    type
    
      { TForm1 }
    
      TForm1 = class(TForm)
        Button1: TButton;
        Datasource1: TDatasource;
        DBGrid1: TDBGrid;
        ZConnection1: TZConnection;
        ZQuery1: TZQuery;
        procedure Button1Click(Sender: TObject);
        procedure FormClose(Sender: TObject; var CloseAction: TCloseAction);
      private
        { private declarations }
      public
        { public declarations }
      end;
    
    var
      Form1: TForm1;
    
    implementation
    
    {$R *.lfm}
    
    { TForm1 }
    
    procedure TForm1.Button1Click(Sender: TObject);
    begin
      ZQuery1.Close;
      ZQuery1.SQL.Clear;
      ZQuery1.SQL.Text:='select * from CUSTOMER';
      ZConnection1.Connected:= true;
      ZQuery1.Open;
    end;
    
    procedure TForm1.FormClose(Sender: TObject; var CloseAction: TCloseAction);
    begin
      ZQuery1.Close;
      ZConnection1.Connected:= false;
    end;
    
    end.

Nun wird man aber in den seltensten Fällen den kompletten Inhalt einer Tabelle benötigen. Nehmen wir an, es sollen nur die Kunden aus den USA angezeigt werden. Dafür müsste die SQL Anweisung wie folgt lauten:

select * from CUSTOMER where COUNTRY = 'USA'

Diese Anweisung werden wir aus zwei Gründen nicht für unser Beispielprogramm verwenden: Zum einen gibt es ein Problem bei der Verwendung des einfachen Anführungszeichens. Der Compiler würde das Anführungszeichen vor USA als schließendes Zeichen betrachten (das erste Zeichen steht ja vor select from...) und damit die SQL Anweisung ungültig machen. Der zweite und gewichtigere Grund ist die Tatsache, dass bei der Entwicklung des Programms noch gar nicht bekannt ist, welche Einschränkung der Anzeige später vorgenommen werden soll. Der Benutzer soll in seiner Flexibilität nicht eingeschränkt werden. Dazu ersetzen wir zunächst 'USA' durch einen Platzhalter:

select * from CUSTOMER where COUNTRY = :COUNTRY

Die Platzhalter sind durch den führenden Doppelpunkt gekennzeichnet. Um dem Benutzer die Eingabe des Filterwertes zu ermöglichen, platzieren sie eine TEdit Komponente (Seite 'Standard' in der Komponentenpalette) auf ihrem Formular. Löschen sie den Wert der 'Text' Eigenschaft. Über die 'Params' Eigenschaft von TZQuery können wir nun mit dem in TEdit eingegebenem Text unseren Platzhalter ersetzen:

ZQuery1.Params.ParamByName('COUNTRY').AsString��:= Edit1.Text;

Der Parameter kann sowohl über seine Position als auch seinen Namen spezifiziert werden. Letzteres dürfte vor allem die Lesbarkeit des Quelltextes verbessern. Insgesamt sollte die Prozedur jetzt so aussehen:

procedure TForm1.Button1Click(Sender: TObject);
    begin
      ZQuery1.Close;
      ZQuery1.SQL.Clear;
      ZQuery1.SQL.Text:= 'select * from CUSTOMER where COUNTRY = :COUNTRY';
      ZQuery1.Params.ParamByName('COUNTRY').AsString := Edit1.Text;
      ZConnection1.Connected:= True;
      ZQuery1.Open;
    end;

Sie können jetzt ruhig mit den Einstellungen ein wenig herumspielen. Wenn sie einen Filterwert eingeben, der in der Datenbank nicht vorhanden ist, dann wird eine leere Tabelle angezeigt. Es können jedoch auch ernsthafte Probleme auftreten. Da bei einer Client-Server-Anwendung üblicherweise Client und Server räumlich getrennt sind, ist meist nicht auf den ersten Blick ersichtlich, warum es zu einem Problem gekommen ist. Ist der Server heruntergefahren worden oder hat nur jemand einen Stecker gezogen? Zugriffe auf eine Datenbank sollten daher immer in eine try ... except und/oder try ... finally Schleife eingebunden werden. Nur so ist sichergestellt, dass Datenbankfehler abgefangen werden können und der Anwender nicht im Regen stehen gelassen wird. Für unsere Beispielanwendung könnte eine rudimentäre Behandlungsroutine wie folgt aussehen:

begin
      try
        ZQuery1.Close;
        ...
        ZQuery1.Open;
      except
        on EDatabaseError do
        begin
          MessageDlg('Fehler','Es ist ein Datenbankfehler aufgetreten.',mtError,[mbOK],0);
          Edit1.Text:='';
        end;
      end;
    end;

Hier wird jedoch nur eine einfache Meldung ausgegeben.

Siehe auch

• ZeosDBO: Informationen zur Installation von Zeos
• Zeos tutorial/de: Informationen über Zeos

From the Free Pascal wiki, page "Database tutorial Zeos1/de", as the Internet Archive kept it on 2025-03-27. Copyright stays with the author who wrote it, according to the old wiki's Licensing page. If you have concerns about this material, message the admin.