Colors

Overview

Since FPC 3.2.0, Free Pascal defines TColor and TColorRec as well as the 140 standard Color names in the Delphi compatible System.UItypes unit, to allow non visual code to use the same type as visual code. Lazarus hasn't caught on yet, because the current Lazarus versions still support 3.0.x.

In the LCL TColor is the standard color type. It is compatible with Delphi's TColor. TColor can represent either an RGB (3x8bit) value, or a system color like clDefault. The LCL can also work with the fpImage system which uses the TFPColor type (which is RGBA (4x16bit), not RGB (3x8bit) like TColor).

Conversions between TColor and RGB values

The Graphics unit provides the following functions:

function Blue(rgb: TColor): BYTE; // does not work on system color
function Green(rgb: TColor): BYTE; // does not work on system color
function Red(rgb: TColor): BYTE; // does not work on system color
function RGBToColor(R, G, B: Byte): TColor;
procedure RedGreenBlue(rgb: TColor; out Red, Green, Blue: Byte); // does not work on system color
function FPColorToTColor(const FPColor: TFPColor): TColor;
function TColorToFPColor(const c: TColor): TFPColor; // does not work on system color
function IsSysColor(AColor: TColorRef): Boolean;

Convert TColor to/from string

Functions to convert strings like "25500" or "$AA0088" or "clNavy" to TColor:

• StringToColor
• StringToColorDef

To convert TColor to a nice string like "clNavy" or "$AA0002":

• ColorToString

Convert TColor to/from HTML string #rrggbb

See code in Convert color to/from HTML.

Table of standard colors

About 20 predefined color constants are provided, which are Delphi-compatible:

In FPC 3.2.0+ defines some other constants for w3c colors in System.Uitypes:

System colors

Example: clInfoBk, clInfoText

System colors are color constants with a special meaning. Their real value depends on the context and theme. They are not simple colors. For example clInfoBk:

Form1.Canvas.Brush.Color:=clInfoBk;  // use the default background brush of a hint window
Form1.Canvas.FillRect(10,10,50,50);

A hint window on MS Windows might have a white background so the above will draw white. On Linux/gtk2 it might be a metallic texture, so the above will draw the texture. If you want to put some text onto this you need a corresponding color like clInfoText, otherwise your text might be unreadable for the user. For example:

Form1.Canvas.Brush.Color:=clInfoBk;  // use the default background brush of a hint window
Form1.Canvas.FillRect(10,10,50,50);
Form1.Canvas.Font.Color:=clInfoText;  // use the default text color of a hint window
Form1.Canvas.TextOut(10,10,'Hint');

The system color clInfoBk can not be used for Pen.Color and not for Font.Color. If you do so the result is undefined and depends on the widgetset and user theme. The same for clInfoText: It can only be used as a Font.Color. Using it as Brush.Color may not work. At the moment all widgetsets allow to use it as Pen.Color too.

Theme changes

When the user switches the theme the system colors changes. A clInfoBk might change from white to blue or from a color to a texture. This change will happen when you allocate a new Brush handle. Keep in mind that a simple assignment Brush.Color:=clInfoBk does not allocate a Brush Handle. The Brush Handle is allocated on use. For example:

Form1.Canvas.Brush.Color:=clInfoBk; // this will not create a new brush handle
Form1.Canvas.FillRect(10,10,50,50); // this will create the brush handle with the currently active theme brush for hint windows
...
// if the theme changes in this moment the Brush.Handle is still allocated with the old values
...
Form1.Canvas.FillRect(10,10,50,50); // this will paint with the old theme brush
Form1.Canvas.Brush.Color:=clInfoBk; // assigning the old value will not create a new brush handle
Form1.Canvas.FillRect(10,10,50,50); // this will paint with the old theme brush
Form1.Canvas.Brush.Color:=clRed;    // assigning a new color, old Handle invalid
Form1.Canvas.Brush.Color:=clInfoBk; // assigning a new color, old Handle invalid
Form1.Canvas.FillRect(10,10,50,50); // this will create a new handle and paint with the new theme

Table of system colors

The following table lists the system colors and their meaning. Using them outside the scope of the definition is undefined and the result depends on the widgetset and theme. For example clDefault is the normal background brush of the used device context. If you want to paint button elements on your own custom controls use the drawing functions of the unit Themes.

Constant

LCL definition

Delphi notes

Supported Widgetsets

clNone

Indicates "do not paint". Using it as Control's color is undefined. The control will not get transparent.

-

all

clDefault

Using it for Brush will use the normal background brush of the target DC (device context).

• On a Form's canvas a FillRect will paint a rectangular area filled with the normal background of a standard window. This is whatever the widgetset and theme defines. This might be the color gray or a gradient or a picture.
• Using clDefault on the Canvas of a TListBox will paint with the normal background, which is normally white on Windows. So in a TListBox clDefault is the same as clWindow.
• Using it as Pen color will use the default line color for the device context.
• Using it as Font color will use the normal text color of the device context.

| -

all

clScrollBar

Scrollbar body

-

all

clBackground

Desktop background color

-

all

clActiveCaption

Active window titlebar

-

none

clInactiveCaption

Inactive window titlebar

-

none

clMenu

Regular menu item background color

-

none

clWindow

The normal background brush of unselected text. Defined for controls like TEdit, TComboBox, TMemo, TListBox, TTreeView.

-

none

clWindowFrame

Color of frame around the window

-

none

clMenuText

The font color to use together with clMenu

-

none

clWindowText

Font color to use together with clWindow

-

none

clCaptionText

Active window titlebar text color

-

none

clActiveBorder

?

-

none

clInactiveBorder

?

-

none

clAppWorkspace

MDIMain form background

-

none

clHighlight

The brush color of selected element

-

none

clHighlightText

Font color of selected text (to use together with clHighligh).

-

none

clBtnFace

Button background

-

none

clBtnShadow

Button shadow color (bottom right) used to achieve 3D effect

-

none

clGrayText

The font color of disabled element

-

none

clBtnText

Button font color to use together with clBtnFace

-

none

clInactiveCaptionText

Inactive window titlebar text color

-

none

clBtnHighlight

Button highlight color (top left) used to achieve 3D effect

-

none

cl3DDkShadow

?

-

none

cl3DLight

?

-

none

clInfoText

Font color for hints. Use together with clInfoBk

-

all

clInfoBk

Brush color for hints. Use together with clInfoText

-

all

clHotLight

?

-

none

clGradientActiveCaption

The second color used to make gradient of active window titlebar

-

none

clGradientInactiveCaption

The second color used to make gradient for inactive window titlebar

-

none

clMenuHighlight

The background color of selected menu item

-

none

clMenuBar

The Backround color of menu bar

-

none

clForm

?

-

none

clColorDesktop

?

-

none

cl3DFace

?

-

none

cl3DShadow

?

-

none

cl3DHiLight

?

-

none

clBtnHiLight

Same as clBtnHighlight

-

none

Finding the rgb values of a system color

Use the function ColorToRGB (in unit Graphics to determine the rgb components of a system color. This functions detects whether a color is a system color and, if this is true, looks up the system color in the themes color. The returned Longint can be understood as a normal color:

// This example has a TColorBox on a form and uses this OnChange handler for the TColorbox:
procedure TForm1.ColorBox1Change(Sender: TObject);
var
  c: TColor;
begin
  c := ColorToRGB(ColorBox1.Selected);
  Caption := Format('R%d G%d B%d', [Red(c), Green(c), Blue(c)]);
end;

Drawing theme elements on your custom controls

The unit Themes provides functions to draw single elements of standard controls. For example to draw an expand sign like a TTreeView use the following code:

uses Themes;

...

procedure TYourCustomControl.Paint;
const
  PlusMinusDetail: array[Boolean {Hot}, Boolean {Expanded}] of TThemedTreeview =
  (
    (ttGlyphClosed, ttGlyphOpened),
    (ttHotGlyphClosed, ttHotGlyphOpened)
  );
var
  Details: TThemedElementDetails;
  R: TRect;
  Collapse: boolean;
begin
  ...
  //draw a themed expand sign.
  Details := ThemeServices.GetElementDetails(PlusMinusDetail[False, Collapse]);
  R := Rect(ALeft, ATop, ARight + 1, ABottom + 1);
  ThemeServices.DrawElement(Canvas.Handle, Details, R, nil);
  ...
end;

From the Free Pascal wiki, page "Colors", as it stood on 2021-04-18 after a change by Marcov, out of the wiki's dump of 2024-05-26. Copyright stays with the author who wrote it, according to the old wiki's Licensing page. If you have concerns about this material, message the admin.