BGRABitmap tutorial 14

This tutorial shows how to use the Canvas2D property of BGRABitmap. Canvas2D is designed to work like the Javascript 2D context of the HTML Canvas object.

First program

Here is a very simple example:

procedure TForm1.FormPaint(Sender: TObject);
var bmp: TBGRABitmap;
    ctx: TBGRACanvas2D;   
begin
  bmp := TBGRABitmap.Create(ClientWidth,ClientHeight,BGRA(210,210,210));

  ctx := bmp.Canvas2D;
  ctx.fillStyle('rgb(240,128,0)');
  ctx.fillRect(30,30,80,60);
  ctx.strokeRect(50,50,80,60);  

  bmp.Draw(Canvas,0,0);
  bmp.Free;
end;

<table>

<tr>

<td bgcolor="#FFFFe0" style="border: 1px solid black; padding: 4px; text-align: center; border-radius:5px" width="30%">

Note that path fonctions are defined in the IBGRAPath interface. The <b>TBGRAPath</b> class of unit BGRAPath1 provides an independent path object that you can use to create shapes. A sample project can be found in BGRABitmap AggPas.

</td>

</tr>

</table>

The bitmap has a Canvas2D property which provides the fillRect and strokeRect function. The fillStyle is defined to orange by specifying a css color string. When the shape is filled, it uses the fill style, and when the border is drawn, it uses the stroke style.

The code above is equivalent to this Javascript code:

 var canvas = document.getElementsByTagName("canvas")[0];
 canvas.width = 200
 canvas.height = 200
 if (canvas.getContext){
   var ctx = canvas.getContext("2d"); 
   ctx.fillStyle = "rgb(240,128,0)";
   ctx.fillRect(30,30,80,60);
   ctx.strokeRect(50,50,80,60);
 }

<figure> <img src="BGRATutorial14a.png" title="BGRATutorial14a.png" /> <figcaption>BGRATutorial14a.png</figcaption> </figure>

Complex shapes

To draw a complex shape, it is necessary to define a path:

  procedure pave();
  begin
    ctx.fillStyle ('rgb(130,100,255)');
    ctx.strokeStyle ('rgb(0,0,255)');
    ctx.beginPath();
    ctx.lineWidth:=2;
    ctx.moveTo(5,5);ctx.lineTo(20,10);ctx.lineTo(55,5);ctx.lineTo(45,18);ctx.lineTo(30,50);
    ctx.closePath();
    ctx.stroke();
    ctx.fill();
  end;  
 
begin
  bmp := TBGRABitmap.Create(ClientWidth,ClientHeight,BGRA(210,210,210));
  ctx := bmp.Canvas2D;
  pave();
  bmp.Draw(Canvas,0,0);
  bmp.Free;
end;

Notice that the line width is defined by the property lineWidth and that the path begins with a beginPath call. If you want more information on the way path works, see the Javascript documentation.

<figure> <img src="Tutorial14b.png" title="Tutorial14b.png" /> <figcaption>Tutorial14b.png</figcaption> </figure>

Using transformations

Now we can draw the triangle six times with a rotation by calling transformation functions.

  procedure six();
  var
    i: Integer;
  begin
     ctx.save();
     for i := 0 to 5 do
     begin
        ctx.rotate(2*PI/6);
        pave();
     end;
     ctx.restore();
  end;
begin
  bmp := TBGRABitmap.Create(ClientWidth,ClientHeight,BGRA(210,210,210));
  ctx := bmp.Canvas2D;
  ctx.translate(80,80);
  six;
  bmp.Draw(Canvas,0,0);
  bmp.Free;
end;

<figure> <img src="BGRATutorial14c.png" title="BGRATutorial14c.png" /> <figcaption>BGRATutorial14c.png</figcaption> </figure>

Gradients and memory usage

To use gradients, Canvas2D provides the createLinearGradient and createPattern functions. Theses functions return an interfaced object. You must not free them explicitely. They are freed when there are no more references to them. For example:

var
  grad: IBGRACanvasGradient2D;
begin
  grad := ctx.createLinearGradient(0,0,320,240);
  grad.addColorStop(0.3, '#ff0000');
  grad.addColorStop(0.6, '#0000ff');
  ctx.fillStyle(grad);

  grad := ctx.createLinearGradient(0,0,320,240);
  grad.addColorStop(0.3, '#ffffff');
  grad.addColorStop(0.6, '#000000');
  ctx.strokeStyle(grad);
  ctx.lineWidth := 5;

  ctx.moveto(160,120);
  ctx.arc(160,120,100,Pi/6,-Pi/6,false);
  ctx.fill();
  ctx.stroke();
end;

The grad variable is assigned with the gradient objects, but there is no call to Free.

<figure> <img src="BGRATutorial14d.png" title="BGRATutorial14d.png" /> <figcaption>BGRATutorial14d.png</figcaption> </figure>

More examples

Other examples are in the testcanvas2d directory of BGRABitmap archive. Scripts are taken from the Jean-Paul Davalan web site (Internet Archive link) which contains HTML Canvas examples.

Previous tutorial (pixel coordinates) Next tutorial (3D)

From the Free Pascal wiki, page "BGRABitmap tutorial 14", as it stood on 2023-05-21 after a change by Circular, out of the wiki's dump of 2024-05-26. Copyright stays with the author who wrote it, according to the old wiki's Licensing page. If you have concerns about this material, message the admin.