Multiplex

Portzugriffe

Wie die Schieberegisterbefehle auf die Ports zugreifen, siehe hier:

• GPIO
• Schieberegister

Beispiel

Bei jedem Timerdurchlauf, wird ein anderes Segment angesteuert. Somit muss der Timer 4 mal durchlaufen, bis ein Frame aktualisiert ist. Für eine konstante Wiederholfrequenz, ist der Timer am besten geeignet, da er regelmässig aufgerufen wird. Man könnte ein Multiplex auch in der Hauptloop machen, aber wen dort eine kleine Pause vorkommt, dann fängt die Anzeige an zu flackern.

Die Ausgabe erfolgt über zwei Schieberegister (74HC595). Wen der AVR genügend GPIO hat, kann man dies auch über diese machen.

Digits Konstante für 7-Segmentanzeige

In dieser Konstante sind die LED-Kombinationen der Ziffern gespeichert. Zusätzlich sind noch HEX-Zeichen gespeichert.

const
  digits: packed array[0..15] of byte = (
  %00111111,  // = 0
  %00000110,  // = 1
  %01011011,  // = 2
  %01001111,  // = 3
  %01100110,  // = 4
  %01101101,  // = 5
  %01111101,  // = 6
  %00000111,  // = 7
  %01111111,  // = 8
  %01100111,  // = 9
  %01110111,  // = a Für Hex-Ausgabe
  %01111100,  // = b
  %00111001,  // = c
  %01011110,  // = d
  %01111001,  // = e
  %01110001); // = f

Werte der einzelnen Segmente

Als Beispiel wird eine 4-stellige 7-Segmentanzeige angesteuert. Wen man einen grösseren Multiplex will, muss man dies Zahl erhöhen.

const
  DigitCount = 4;
var
  Number: array[0..DigitCount - 1] of byte;

Multiplex

Das ist das Herz des Multiplexes. Bei jedem Durchlauf des Timers, wird das Segment gewechselt. Wen man dies sehen will, muss man die Timerfrequenz reduzieren, das man dies von Auge sieht. Für dieses Beispiel wird der Timer0 verwendet.

  procedure Timer0_Interrupt; public Name 'TIM0_COMPA_ISR'; interrupt;
  const
    segPos: byte = 0;
  begin
    segPos := segPos + 1;
    if (segPos > DigitCount - 1) then begin
      segPos := 0;
    end;

    WritePortA(latchPin, False);
    WritePortA(latchPin, True);

    shiftOut595(digits[Number[segPos]]); // Aktuelle Ziffer im Segment ansteuern.
    shiftOut595(1 shl segPos);           // Aktuelles Segment aktivieren.
  end;

Delay

Ein einfaches Delay. dies wird beim Zifferwechsel in der Hauptschleife benötigt.

procedure delay;
var
  i: integer;
begin
  for i := 0 to 200 do asm Nop END;
end;

Initialisierung und Hauptschleife

Hier der Timer0 für den Mutiplex initialisiert, auch werden die benötigten Port auf Ausgabe geschalten.

Genaueres über Timer hier:

• Timer

Dieses Beispiel gibt Abwechselnd 1234 und 5678 aus.

begin
  // Interrupt sperren.
  asm cli END;

  // Ports auf Ausgabe schalten.
  DDRA := (1 shl dataOutPin) or (1 shl latchPin) or (1 shl clockPin);

  // -- Timer initialisieren
  TCCR0A := (1 shl 1);
  TCCR0B := TCCR0B or %101;
  TIMSK0 := TIMSK0 or (1 shl OCIE0A);

  // Interrupt frei geben.
  asm sei END;

  // Hauptschleife
  repeat
    Number[0] := 1;
    Number[1] := 2;
    Number[2] := 3;
    Number[3] := 4;
    delay;

    Number[0] := 5;
    Number[1] := 6;
    Number[2] := 7;
    Number[3] := 8;
    delay;
  until 1 = 2;
end;

Siehe auch

• Übersichtseite AVR Embedded Tutorial

Autor: Mathias

From the Free Pascal wiki, page "AVR Embedded Tutorial - Multiplex/de", as it stood on 2020-02-02 after a change by Trev, out of the wiki's dump of 2024-05-26. Copyright stays with the author who wrote it, according to the old wiki's Licensing page. If you have concerns about this material, message the admin.