There is documentation about how to add tabs and controls in the designer but I could not find any explanation of how to do the same programatically. I have a TPageControl on my form and at runtime I want to add a new page with a SynEdit on it.

This is what I have so far:

procedure TForm1.AddTab(AFileName: String);
var
  Sheet: TTabSheet;
  Ed: TSynEdit;
begin
  Sheet := PageControl.AddTabSheet;
  Sheet.Caption := 'Unnamed';
  Ed := TSynEdit.Create(Sheet);
end;

But it does not work. It will add a new Tab and set its caption but the tab will be empty. I have tried Ed.Show and also tried to change its position and size but nothing helps. I also tried with a simple TButton instead of a TSynEdit but this also does not work. What am I missing here?

Bernd

What am I missing here?

Ed.parent:=Sheet;

Ludo

Try this:

procedure TForm1.AddTab(AFileName: String);
var
   Sheet: TTabSheet;
   Ed: TSynEdit;
begin
   Sheet := TTabSheet.Create(pagecontrol1);
   sheet.Parent := PageControl1;
   Sheet.Caption := 'Unnamed';
   Ed := TSynEdit.Create(Sheet);
   ed.Parent := Sheet;
   ed.BoundsRect := sheet.BoundsRect;
   ed.LineText := 'specimen line';
   PageControl1.ActivePage := Sheet;
end;

Hint:
You don't need the Delphism "set Parent first" under LCL. The above will create a lot of updates.

procedure TForm1.AddTab(AFileName: String);
var
  Sheet: TTabSheet;
  Ed: TSynEdit;
begin
  Sheet := TTabSheet.Create(pagecontrol1);
  Sheet.Caption := 'Unnamed';
  Ed := TSynEdit.Create(Sheet);
  ed.Align := alClient; // fill the whole sheet
  ed.LineText := 'specimen line';
  ed.Parent := Sheet;
  PageControl1.ActivePage := Sheet;
  sheet.Parent := PageControl1; // set Parent as last to reduce updates
end;

Mattias

Thanks for the hint. I would not have known that from reading the wiki - I think it is worth documenting there somewhere.

I added a note to TWinControl.Parent.

Mattias