Hi!

Has anyone translated the XTest xtension of XFree86 to pascal yet?

I tried to h2pas this:
/usr/X11R6/include/X11/extensions/XTest.h

but don't know how to handle the "#if NeedFunctionPrototypes" declarations. I think they have to be rebuild as function headers with modifiers "extern; cdecl"?

TIA,
Marc

Has anyone translated the XTest xtension of XFree86 to pascal yet?

I think it would look something like this:

unit XTest;
interface
uses x, xlib;
const
  X_XTestGetVersion = 0;
  X_XTestCompareCursor = 1;
  X_XTestFakeInput = 2;
  X_XTestGrabControl = 3;
  XTestNumberEvents = 0;
  XTestNumberErrors = 0;
  XTestMajorVersion = 2;
  XTestMinorVersion = 2;
  XTestExtensionName = 'XTEST';
type
  Bool =LongInt;
  TXInputClassInfo = record
    input_class : byte;
    event_type_base : byte;
  end;
  PXInputClassInfo = ^TXInputClassInfo;
  TXDevice = record
    device_id : TXID;
    num_classes : longint;
    classes : PXInputClassInfo;
  end;
  PXDevice = ^TXDevice;
function XTestQueryExtension(dpy:PDisplay; event_basep:Plongint; error_basep:Plongint;
  majorp:Plongint; minorp:Plongint):Bool;cdecl;external;
function XTestCompareCursorWithWindow(dpy:PDisplay; window:TWindow;
  cursor:TCursor):Bool;cdecl;external;
function XTestCompareCurrentCursorWithWindow(dpy:PDisplay;
  win:TWindow):Bool;cdecl;external;
function XTestFakeKeyEvent(dpy:PDisplay; keycode:dword; is_press:Bool;
  delay:dword):longint;cdecl;external;
function XTestFakeButtonEvent(dpy:PDisplay; button:dword; is_press:Bool;
  delay:dword):longint;cdecl;external;
function XTestFakeMotionEvent(dpy:PDisplay; screen:longint; x:longint; y:longint;
  delay:dword):longint;cdecl;external;
function XTestFakeRelativeMotionEvent(dpy:PDisplay; x:longint; y:longint;
  delay:dword):longint;cdecl;external;
function XTestFakeDeviceKeyEvent(dpy:PDisplay; dev:PXDevice; keycode:dword;
  is_press:Bool; axes:Plongint; n_axes:longint; delay:dword):longint;cdecl;external;
function XTestFakeDeviceButtonEvent(dpy:PDisplay; dev:PXDevice; button:dword;
  is_press:Bool; axes:Plongint; n_axes:longint; delay:dword):longint;cdecl;external;
function XTestFakeProximityEvent(dpy:PDisplay; dev:PXDevice;in_prox :Bool; axes:Plongint;
  n_axes:longint; delay :dword):longint;cdecl;external;
function XTestFakeDeviceMotionEvent(dpy:PDisplay; dev:PXDevice; is_relative:Bool;
  first_axis:longint; axes:Plongint; n_axes :longint; delay:dword):longint;cdecl;external;
function XTestGrabControl(dpy:PDisplay; impervious:Bool):longint;cdecl;external;
procedure XTestSetGContextOfGC(gc:TGC; gid:TGContext);cdecl;external;
procedure XTestSetVisualIDOfVisual(visual:PVisual; visualid:TVisualID);cdecl;external;
function XTestDiscard(dpy:PDisplay):TStatus;cdecl;external;
implementation
end.

( compiles, but not tested )

- Jeff

__________________________________
Do you Yahoo!?
Yahoo! Mail - More reliable, more storage, less spam http://mail.yahoo.com

[...code snipped...]

( compiles, but not tested ) - Jeff

It does compile. Wow!

So I'll go testing, stay tuned for the result ...

Thank you, Jeff.

Bye,
Marc

> Has anyone translated the XTest xtension of XFree86 to pascal yet? I think it would look something like this:

[...]

( compiles, but not tested )

I have only tested 'XTestFakeKeyEvent' so far and it does work!

Besides linking against Xtst (fpc -k-lXtst ...) there is only the problem of recoding chars to XKeySym's, but I think this is possible.

Bye and a big thanks again,
Marc

Am Mi, den 17.03.2004 schrieb Marc Santhoff um 10:18: [...]

It does compile. Wow! So I'll go testing, stay tuned for the result ...

It is only stupid rubbish, but i works.

For reference i use the source of the tool "xte" from the "xautomation" suite (see: http://hoopajoo.net/projects/xautomation.html).

Look:

program xtesttest;
uses sysutils, x, xlib, XTest;
var
	toSend : AnsiString;
	ch	   : AnsiString;
	i	   : integer;
	dpy	   : PDisplay;
	ks	   : TKeySym;
	kc	   : TKeyCode;
BEGIN
	dpy := XOpenDisplay(NIL);
	if NOT(dpy = NIL) then begin
		toSend := 'lalalalala';
		for i:= 0 to length(toSend)-1 do begin
			ch := copy(toSend,i+1,1);
			writeln(ch);
			ks := XStringToKeysym(pchar(ch));
			kc := XKeySymToKeycode( dpy, ks );
			XTestFakeKeyEvent( dpy, kc, longint(TRUE), CurrentTime );
			XTestFakeKeyEvent( dpy, kc, longint(FALSE), CurrentTime );
		end;
		XCloseDisplay( dpy );
	end;
END.

As already written, link against Xtst (fpc -k-lXtst ...).

Have fun,
Marc

Hi!

Only a question of interest:
Are you trying to get FPC compiling X11 apps?

On Wed, 17 Mar 2004, Marc Santhoff wrote:

| Am Mi, den 17.03.2004 schrieb Jeff Pohlmeyer um 08:05: | > > Has anyone translated the XTest xtension of XFree86 to pascal yet? | >
| > I think it would look something like this:
| [...]
| >
| > ( compiles, but not tested )
|
| I have only tested 'XTestFakeKeyEvent' so far and it does work! |
| Besides linking against Xtst (fpc -k-lXtst ...) there is only the | problem of recoding chars to XKeySym's, but I think this is possible. |
| Bye and a big thanks again,
| Marc
|
|
|
| _______________________________________________
| fpc-pascal maillist -
| http://lists.freepascal.org/mailman/listinfo/fpc-pascal |

mfg

Ing. Rainer Hantsch

Hi! Only a question of interest: Are you trying to get FPC compiling X11 apps?

Nope, I;m not trying but doing it actually. ;)

Yes, ask questions, if you like to.

Bye,
Marc

Hi! Only a question of interest: Are you trying to get FPC compiling X11 apps?

What I'm doing is to write some sort of virtual keyboard (e.g. on a touch screen) and post the event to the X server.

Ebenfalls freundliche Grüße,
Marc

Hello, Marc!

Do you have some code for me to see how FPC programs for X11 are written?

Nothing special, keep it simple, I primarily want to... a.) see if it works with my old FPC 1.0.4
(yes, I still use this old version because it is the latest one which also works on SuSE 5.2)
b.) see how complicated it is.
Open a window, doo some little things inside,...

On Thu, 18 Mar 2004, Marc Santhoff wrote:

| Am Do, den 18.03.2004 schrieb Rainer Hantsch um 10:40: | > Hi!
| >
| > Only a question of interest:
| > Are you trying to get FPC compiling X11 apps?
|
| Nope, I;m not trying but doing it actually. ;)
|
| Yes, ask questions, if you like to.
|
| Bye,
| Marc
|
|
|
|
| _______________________________________________
| fpc-pascal maillist -
| http://lists.freepascal.org/mailman/listinfo/fpc-pascal |

mfg

Ing. Rainer Hantsch

Hello, Marc!

Hi!

It should, if not there would be no GUI library at all.

b.) see how complicated it is. Open a window, doo some little things inside,...

no idea, see below...

I think I'm not doing what you think about it (see my other answer):

The goal was to get a GTK+1.2 programme running without a standard keyboard. Jeff Pohlmeyer kindly translated the header for the XTest-extension which I'm using in the following way:

- a microcontroller picks up events from a matrix keyboard
- these event are sent as simple byte streams via USB to the generic system device
- the gtk eventloop has the /dev/ugen0 port selected in an additional input listener
- if there is an event, the callback is invoked by gtk
- the callback decodes the bytestream to a valid XKeySym
- this keysym is inserted in the XServers event loop by the XTest extension

This part is working fine.

For getting an idea (and concept, to be honest) I used the source of "xautomation" (no link at hand, sorry) which was translateable to pascal mostly 1:1.

From the impressions of using X directly i think it should be rather

simple to get started with some C code (AFAIR the X intrinsics docs should have some). But, as said, my program is gtk-based.

So, look at this (not quite what you asked for ;):

procedure FakeKeyDecodeDown(display :  PDisplay; key: AnsiString );
var
	key2 : AnsiString;
	kmod : AnsiString;
begin
	kmod := '';
	key2 := handleCombined(key, kmod);
	{$ifdef debug}writeln('FakeSendKey down: '+key+' '+kmod);{$endif}
	XTestFakeKeyEvent( display, FakeDecodeKey(display, key2), longint(TRUE), CurrentTime );
	FlushDisplay( display );
end; { keyDown }
procedure FakeKeyDecodeUp(display	:  PDisplay; key: AnsiString );
var
	key2 : AnsiString;
	kmod : AnsiString;
begin
	kmod := '';
	key2 := handleCombined(key, kmod);
	{$ifdef debug}writeln('FakeSendKey up: '+key+' '+kmod);{$endif}
	XTestFakeKeyEvent( display, FakeDecodeKey(display, key), longint(FALSE), CurrentTime );
	FlushDisplay( display );
end; { keyUp }
function FakeDecodeKey(display : PDisplay; key: AnsiString ):TKeyCode;
var
	ks : TKeySym;
	kc : TKeyCode;
begin
	ks := XStringToKeysym(pchar(key));
	kc := XKeySymToKeycode( display, ks );
	result := kc;
end; { decodeKey }
procedure FlushDisplay(display	: PDisplay);
begin
	XFlush(display);
end; { FakeFlush }

Some lenghtly parts are missing and the XTest unit is unchanged from Jeffs positing (I think, I'll diff it if important)

"handleCombined" does some decoding as in xte from xautomation (Shift, '&' -> 'ampersand', ...)

When I'm back from my vacation beginning tomorrow, maybe I can help a little in translating a basic window C code to pascal.

Bye,
Marc