Sign in Join
FPDoc Onlineexperiment

CompareStr function

In unit sysutils

Compare 2 ansistrings case-sensitively, ignoring special characters.

Declaration

pascal
function CompareStr(const S1: string; const S2: string): Integer
 ; overload

Description

CompareStr compares two strings, S1 and S2, and returns the following result:

<0
if S1<S2.
0
if S1=S2.
>0
if S1>S2.

The comparison of the two strings is case-sensitive. The function does not take internationalization settings into account, it simply compares ASCII values.

Errors

None.

See also

Example: ex65

pascal
Program Example65;

{ This program demonstrates the CompareStr function }
{$H+}

Uses sysutils;

Procedure TestIt (S1,S2 : String);

Var R : Longint;

begin
  R:=CompareStr(S1,S2);
  Write ('"',S1,'" is ');
  If R<0 then
    write ('less than ')
  else If R=0 then
    Write ('equal to ')
  else
    Write ('larger than ');
  Writeln ('"',S2,'"');
end;

Begin
  Testit('One string','One smaller string');
  Testit('One string','one string');
  Testit('One string','One string');
  Testit('One string','One tall string');
End.

An experiment, built from development snapshots. Not the official Free Pascal or Lazarus documentation.